CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.18 FATAL_ERROR)
   2 project(gost-engine LANGUAGES C)
   3
   4 include(GNUInstallDirs)
   5 include(CheckLibraryExists)
   6 include(CheckFunctionExists)
   7 include(CheckCSourceRuns)
   8
   9 enable_testing()
  10
  11 find_package(OpenSSL 3.0 REQUIRED)
  12
  13 if (NOT DEFINED OPENSSL_ROOT_DIR)
  14   get_filename_component(OPENSSL_ROOT_DIR ${OPENSSL_INCLUDE_DIR} DIRECTORY)
  15   message(STATUS "Setting OpenSSL root: ${OPENSSL_ROOT_DIR}")
  16 endif()
  17 find_program(OPENSSL_PROGRAM openssl
  18   PATHS ${OPENSSL_ROOT_DIR} PATH_SUFFIXES apps bin NO_DEFAULT_PATH)
  19 message(STATUS "Found OpenSSL application: ${OPENSSL_PROGRAM}")
  20 include_directories(${OPENSSL_INCLUDE_DIR})
  21 set(OPENSSL_MODULES_DIR ${CMAKE_INSTALL_LIBDIR}/ossl-modules)
  22
  23 if (CMAKE_C_COMPILER_ID MATCHES "Clang")
  24   set(CMAKE_C_FLAGS_RELEASE -O2)
  25   set(CMAKE_C_FLAGS_DEBUG "-O0 -ggdb")
  26   set(CMAKE_C_FLAGS_RELWITHDEBINFO "-O2 -ggdb")
  27   add_compile_options(-Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -Qunused-arguments -Wno-deprecated-declarations)
  28 elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
  29   set(CMAKE_C_FLAGS_RELEASE -O2)
  30   set(CMAKE_C_FLAGS_DEBUG "-O0 -ggdb")
  31   set(CMAKE_C_FLAGS_RELWITHDEBINFO "-O2 -ggdb")
  32   add_compile_options(-Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -Wno-error=unknown-pragmas -Wno-error=pragmas -Wno-deprecated-declarations)
  33 elseif(CMAKE_C_COMPILER_ID MATCHES "MSVC")
  34   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
  35   add_definitions(-D_CRT_DEPRECATED_NO_WARNINGS)
  36   add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
  37   add_compile_options(/MP /WX /W4 /wd4100 /wd4267 /wd4206 /wd4706 /wd4244 /wd4115 /wd4996)
  38 endif()
  39
  40 if (ASAN)
  41   message(STATUS "address sanitizer enabled")
  42   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=address -g3 -fno-omit-frame-pointer")
  43   set(SKIP_PERL_TESTS 1)
  44 endif()
  45
  46 # DEPRECATEDIN_3_0 CMAC
  47 set_source_files_properties(gost_omac.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  48 # DEPRECATEDIN_3_0 HMAC
  49 set_source_files_properties(gost_keyexpimp.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  50
  51 set(CMAKE_C_STANDARD 90)
  52 CHECK_FUNCTION_EXISTS(clock_gettime HAVE_CLOCK_GETTIME_C)
  53 CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_CLOCK_GETTIME_RT)
  54 if(HAVE_CLOCK_GETTIME_RT AND NOT HAVE_CLOCK_GETTIME_C)
  55   set(CLOCK_GETTIME_LIB rt)
  56 endif()
  57
  58 include (TestBigEndian)
  59 TEST_BIG_ENDIAN(IS_BIG_ENDIAN)
  60 if(IS_BIG_ENDIAN)
  61  message(STATUS "BIG_ENDIAN")
  62 else()
  63  message(STATUS "LITTLE_ENDIAN")
  64  add_definitions(-DL_ENDIAN)
  65 endif()
  66
  67 check_c_source_runs("
  68   #ifdef _MSC_VER
  69   # include <intrin.h>
  70   #else
  71   # include <x86intrin.h>
  72   #endif
  73   int main(void) {
  74     unsigned long long x = -1, y = 1, r;
  75     unsigned char cf;
  76     cf = _addcarry_u64(1, x, y, &r);
  77     return !(cf == 1 && r == 1);
  78   }
  79   " ADDCARRY_U64)
  80 if (ADDCARRY_U64)
  81   add_definitions(-DHAVE_ADDCARRY_U64)
  82 endif()
  83
  84 check_c_source_runs("
  85   int main(void) {
  86     char buf[16] = { 0, 1, 2 };
  87     int *p = (int *)(buf + 1);
  88     int *q = (int *)(buf + 2);
  89     return (*p == *q);
  90   }
  91   " RELAXED_ALIGNMENT)
  92 if (NOT RELAXED_ALIGNMENT)
  93   add_definitions(-DSTRICT_ALIGNMENT)
  94 endif()
  95
  96 set(BIN_DIRECTORY bin)
  97
  98 set(OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${BIN_DIRECTORY})
  99
 100 #set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 101 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 102 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 103
 104 # Remove when https://gitlab.kitware.com/cmake/cmake/issues/18525 is addressed
 105 set(OPENSSL_ENGINES_DIR "" CACHE PATH "OpenSSL Engines Directory")
 106 if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
 107         include(FindPkgConfig)
 108         pkg_get_variable(OPENSSL_ENGINES_DIR libcrypto enginesdir)
 109         if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
 110                 message( FATAL_ERROR "Unable to discover the OpenSSL engines directory. Provide the path using -DOPENSSL_ENGINES_DIR" )
 111         endif()
 112 endif()
 113
 114 set(GOST_89_SOURCE_FILES
 115         gost89.c
 116         gost89.h
 117         )
 118
 119 set(GOST_HASH_SOURCE_FILES
 120         gosthash.c
 121         gosthash.h
 122         )
 123
 124 set(GOST_HASH_2012_SOURCE_FILES
 125         gosthash2012.c
 126         gosthash2012.h
 127         gosthash2012_const.h
 128         gosthash2012_precalc.h
 129         gosthash2012_ref.h
 130         gosthash2012_sse2.h
 131         )
 132
 133 set(GOST_GRASSHOPPER_SOURCE_FILES
 134         gost_grasshopper.h
 135         gost_grasshopper_core.h
 136         gost_grasshopper_core.c
 137         gost_grasshopper_defines.h
 138         gost_grasshopper_defines.c
 139         gost_grasshopper_math.h
 140         gost_grasshopper_galois_precompiled.c
 141         gost_grasshopper_precompiled.c
 142         gost_grasshopper_cipher.h
 143         gost_grasshopper_cipher.c
 144         )
 145
 146 set(GOST_ERR_SOURCE_FILES
 147         e_gost_err.c
 148         e_gost_err.h
 149         )
 150
 151 set(GOST_CORE_SOURCE_FILES
 152         gost_ameth.c
 153         gost_pmeth.c
 154         gost_ctl.c
 155         gost_asn1.c
 156         gost_crypt.c
 157         gost_keywrap.c
 158         gost_keywrap.h
 159         gost_md.c
 160         gost_md2012.c
 161         gost_omac.c
 162         gost_omac_acpkm.c
 163         gost_gost2015.c
 164         gost_lcl.h
 165         gost_params.c
 166         gost_keyexpimp.c
 167         )
 168
 169 set(GOST_EC_SOURCE_FILES
 170         gost_ec_keyx.c
 171         gost_ec_sign.c
 172         ecp_id_GostR3410_2001_CryptoPro_A_ParamSet.c
 173         ecp_id_GostR3410_2001_CryptoPro_B_ParamSet.c
 174         ecp_id_GostR3410_2001_CryptoPro_C_ParamSet.c
 175         ecp_id_GostR3410_2001_TestParamSet.c
 176         ecp_id_tc26_gost_3410_2012_256_paramSetA.c
 177         ecp_id_tc26_gost_3410_2012_512_paramSetA.c
 178         ecp_id_tc26_gost_3410_2012_512_paramSetB.c
 179         ecp_id_tc26_gost_3410_2012_512_paramSetC.c
 180         )
 181
 182 set (GOST_OMAC_SOURCE_FILES
 183         gost_omac.c
 184         gost_omac_acpkm.c
 185         )
 186
 187 set(GOST_LIB_SOURCE_FILES
 188         ${GOST_CORE_SOURCE_FILES}
 189         ${GOST_89_SOURCE_FILES}
 190         ${GOST_HASH_SOURCE_FILES}
 191         ${GOST_HASH_2012_SOURCE_FILES}
 192         ${GOST_GRASSHOPPER_SOURCE_FILES}
 193         ${GOST_EC_SOURCE_FILES}
 194         ${GOST_OMAC_SOURCE_FILES}
 195         )
 196
 197 set(GOST_ENGINE_SOURCE_FILES
 198         gost_eng.c
 199         )
 200
 201 set(GOST_PROV_SOURCE_FILES
 202         gost_prov.c
 203         gost_prov_cipher.c
 204         gost_prov_digest.c
 205         gost_prov_mac.c
 206         )
 207
 208 set(TEST_ENVIRONMENT_COMMON
 209         CMAKE_CURRENT_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}
 210         PERL5LIB=${CMAKE_CURRENT_SOURCE_DIR}/test
 211         OPENSSL_PROGRAM=${OPENSSL_PROGRAM}
 212         OPENSSL_CRYPTO_LIBRARY=${OPENSSL_CRYPTO_LIBRARY}
 213         )
 214
 215 set(TEST_ENVIRONMENT_ENGINE
 216         ${TEST_ENVIRONMENT_COMMON}
 217         OPENSSL_ENGINES=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 218         OPENSSL_CONF=${CMAKE_CURRENT_SOURCE_DIR}/test/engine.cnf
 219         )
 220
 221 set(TEST_ENVIRONMENT_PROVIDER
 222         ${TEST_ENVIRONMENT_COMMON}
 223         OPENSSL_MODULES=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 224         OPENSSL_CONF=${CMAKE_CURRENT_SOURCE_DIR}/test/provider.cnf
 225         )
 226
 227 add_executable(test_digest test_digest.c)
 228 target_link_libraries(test_digest OpenSSL::Crypto)
 229 add_test(NAME digest-with-engine COMMAND test_digest)
 230 set_tests_properties(digest-with-engine
 231   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 232 add_test(NAME digest-with-provider COMMAND test_digest)
 233 set_tests_properties(digest-with-provider
 234   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 235
 236 add_executable(test_ciphers test_ciphers.c)
 237 target_link_libraries(test_ciphers OpenSSL::Crypto)
 238 add_test(NAME ciphers-with-engine COMMAND test_ciphers)
 239 set_tests_properties(ciphers-with-engine
 240   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 241 add_test(NAME ciphers-with-provider COMMAND test_ciphers)
 242 set_tests_properties(ciphers-with-provider
 243   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 244
 245 # test_curves is an internals testing program, it doesn't need a test env
 246 add_executable(test_curves test_curves.c)
 247 target_link_libraries(test_curves gost_core gost_err)
 248 add_test(NAME curves COMMAND test_curves)
 249
 250 add_executable(test_params test_params.c)
 251 target_link_libraries(test_params OpenSSL::Crypto)
 252 add_test(NAME parameters-with-engine COMMAND test_params)
 253 set_tests_properties(parameters-with-engine
 254   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 255
 256 add_executable(test_derive test_derive.c)
 257 target_link_libraries(test_derive OpenSSL::Crypto)
 258 add_test(NAME derive-with-engine COMMAND test_derive)
 259 set_tests_properties(derive-with-engine
 260   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 261
 262 add_executable(test_sign test_sign.c)
 263 target_link_libraries(test_sign OpenSSL::Crypto)
 264 add_test(NAME sign/verify-with-engine COMMAND test_sign)
 265 set_tests_properties(sign/verify-with-engine
 266   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 267
 268 add_executable(test_tls test_tls.c)
 269 target_link_libraries(test_tls OpenSSL::SSL)
 270 add_test(NAME TLS-with-engine COMMAND test_tls)
 271 set_tests_properties(TLS-with-engine
 272   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 273
 274 add_executable(test_context test_context.c)
 275 target_link_libraries(test_context OpenSSL::Crypto)
 276 add_test(NAME context-with-engine COMMAND test_context)
 277 set_tests_properties(context-with-engine
 278   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 279 add_test(NAME context-with-provider COMMAND test_context)
 280 set_tests_properties(context-with-provider
 281   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 282
 283 # test_keyexpimp is an internals testing program, it doesn't need a test env
 284 add_executable(test_keyexpimp test_keyexpimp.c)
 285 #target_compile_definitions(test_keyexpimp PUBLIC -DOPENSSL_LOAD_CONF)
 286 target_link_libraries(test_keyexpimp gost_core gost_err)
 287 add_test(NAME keyexpimp COMMAND test_keyexpimp)
 288
 289 # test_gost89 is an internals testing program, it doesn't need a test env
 290 add_executable(test_gost89 test_gost89.c)
 291 target_link_libraries(test_gost89 gost_core gost_err)
 292 add_test(NAME gost89 COMMAND test_gost89)
 293
 294 if(NOT SKIP_PERL_TESTS)
 295     execute_process(COMMAND perl -MTest2::V0 -e ""
 296         ERROR_QUIET RESULT_VARIABLE HAVE_TEST2_V0)
 297     if(NOT HAVE_TEST2_V0)
 298         add_test(NAME engine
 299             COMMAND prove --merge -PWrapOpenSSL ${CMAKE_CURRENT_SOURCE_DIR}/test :: engine)
 300         set_tests_properties(engine PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 301         add_test(NAME provider
 302             COMMAND prove --merge -PWrapOpenSSL ${CMAKE_CURRENT_SOURCE_DIR}/test :: provider)
 303         set_tests_properties(provider PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 304     else()
 305         message(STATUS "No Test2::V0 perl module (engine and provider tests skipped)")
 306     endif()
 307 endif()
 308
 309 add_executable(sign benchmark/sign.c)
 310 target_link_libraries(sign gost_core gost_err ${CLOCK_GETTIME_LIB})
 311
 312 # All that may need to load just built engine will have path to it defined.
 313 set(BINARY_TESTS_TARGETS
 314         test_digest
 315         test_ciphers
 316         test_curves
 317         test_params
 318         test_derive
 319         test_sign
 320         test_context
 321         test_keyexpimp
 322         test_gost89
 323         test_tls
 324         )
 325 set_property(TARGET ${BINARY_TESTS_TARGETS} APPEND PROPERTY COMPILE_DEFINITIONS ENGINE_DIR="${OUTPUT_DIRECTORY}")
 326
 327 add_library(gost_core STATIC ${GOST_LIB_SOURCE_FILES})
 328 set_target_properties(gost_core PROPERTIES POSITION_INDEPENDENT_CODE ON)
 329 target_link_libraries(gost_core PRIVATE OpenSSL::Crypto)
 330 add_library(gost_err STATIC ${GOST_ERR_SOURCE_FILES})
 331 set_target_properties(gost_err PROPERTIES POSITION_INDEPENDENT_CODE ON)
 332 target_link_libraries(gost_err PRIVATE OpenSSL::Crypto)
 333
 334 # The GOST engine in module form
 335 add_library(gost_engine MODULE ${GOST_ENGINE_SOURCE_FILES})
 336 # Set the suffix explicitly to adapt to OpenSSL's idea of what a
 337 # module suffix should be
 338 set_target_properties(gost_engine PROPERTIES
 339   PREFIX "" OUTPUT_NAME "gost" SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX})
 340 target_link_libraries(gost_engine PRIVATE gost_core gost_err)
 341
 342 # The GOST engine in library form
 343 add_library(lib_gost_engine SHARED ${GOST_ENGINE_SOURCE_FILES})
 344 set_target_properties(lib_gost_engine PROPERTIES
 345   COMPILE_DEFINITIONS "BUILDING_ENGINE_AS_LIBRARY"
 346   PUBLIC_HEADER gost-engine.h
 347   OUTPUT_NAME "gost")
 348 target_link_libraries(lib_gost_engine PRIVATE gost_core gost_err)
 349
 350
 351 # The GOST provider uses this
 352 add_subdirectory(libprov)
 353
 354 # The GOST provider in module form
 355 add_library(gost_prov MODULE
 356   ${GOST_PROV_SOURCE_FILES} ${GOST_ENGINE_SOURCE_FILES}
 357   )
 358 set_target_properties(gost_prov PROPERTIES
 359   PREFIX "" OUTPUT_NAME "gostprov" SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX}
 360   COMPILE_DEFINITIONS "BUILDING_GOST_PROVIDER;OPENSSL_NO_DYNAMIC_ENGINE"
 361   )
 362 target_link_libraries(gost_prov PRIVATE gost_core libprov)
 363
 364 # The GOST provider in library form
 365 add_library(lib_gost_prov SHARED
 366   ${GOST_PROV_SOURCE_FILES} ${GOST_ENGINE_SOURCE_FILES}
 367   )
 368 set_target_properties(lib_gost_prov PROPERTIES
 369   OUTPUT_NAME "gostprov"
 370   COMPILE_DEFINITIONS "BUILDING_GOST_PROVIDER;BUILDING_PROVIDER_AS_LIBRARY;OPENSSL_NO_DYNAMIC_ENGINE"
 371   )
 372 target_link_libraries(lib_gost_prov PRIVATE gost_core libprov)
 373
 374 set(GOST_SUM_SOURCE_FILES
 375         gostsum.c
 376         )
 377
 378 add_executable(gostsum ${GOST_SUM_SOURCE_FILES})
 379 target_link_libraries(gostsum gost_core gost_err)
 380
 381 set(GOST_12_SUM_SOURCE_FILES
 382         gost12sum.c
 383         )
 384
 385 add_executable(gost12sum ${GOST_12_SUM_SOURCE_FILES})
 386 target_link_libraries(gost12sum gost_core gost_err)
 387
 388 set_source_files_properties(tags PROPERTIES GENERATED true)
 389 add_custom_target(tags
 390     COMMAND ctags -R . ${OPENSSL_ROOT_DIR}
 391     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 392
 393 add_custom_target(tcl_tests
 394     COMMAND OPENSSL_LIBCRYPTO=${OPENSSL_CRYPTO_LIBRARY}
 395             OPENSSL_APP=${OPENSSL_PROGRAM}
 396             TESTSRC=${CMAKE_SOURCE_DIR}/tcl_tests
 397             TESTDIR=${CMAKE_BINARY_DIR}/tcl_tests
 398             ENGINE_DIR=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 399             sh ./runtest.sh
 400     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/tcl_tests)
 401
 402 add_executable(test_tlstree test_tlstree.c)
 403 target_link_libraries(test_tlstree PUBLIC OpenSSL::Crypto)
 404
 405 # install programs and manuals
 406 install(TARGETS gostsum gost12sum RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 407 install(FILES gostsum.1 gost12sum.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)
 408
 409 # install engine in library and module form
 410 install(TARGETS lib_gost_engine EXPORT GostEngineConfig LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 411 install(TARGETS gost_engine EXPORT GostEngineConfig
 412         LIBRARY  DESTINATION ${OPENSSL_ENGINES_DIR}
 413         RUNTIME  DESTINATION ${OPENSSL_ENGINES_DIR})
 414 # install provider in library and module form
 415 install(TARGETS lib_gost_prov EXPORT GostProviderConfig
 416         LIBRARY  DESTINATION ${CMAKE_INSTALL_LIBDIR})
 417 install(TARGETS gost_prov EXPORT GostProviderConfig
 418         LIBRARY  DESTINATION ${OPENSSL_MODULES_DIR}
 419         RUNTIME  DESTINATION ${OPENSSL_MODULES_DIR})
 420 if (MSVC)
 421   install(FILES $<TARGET_PDB_FILE:lib_gost_engine>
 422     EXPORT GostEngineConfig DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 423   install(FILES $<TARGET_PDB_FILE:gostsum> $<TARGET_PDB_FILE:gost12sum>
 424     EXPORT GostEngineConfig DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 425   install(FILES $<TARGET_PDB_FILE:gost_engine>
 426     EXPORT GostEngineConfig DESTINATION ${OPENSSL_ENGINES_DIR} OPTIONAL)
 427   install(FILES $<TARGET_PDB_FILE:lib_gost_prov>
 428     EXPORT GostProviderConfig DESTINATION ${CMAKE_INSTALL_LIBDIR} OPTIONAL)
 429   install(FILES $<TARGET_PDB_FILE:gost_prov>
 430     EXPORT GostProviderConfig DESTINATION ${OPENSSL_MODULES_DIR} OPTIONAL)
 431 endif()
 432 install(EXPORT GostEngineConfig DESTINATION GostEngine/share/cmake/GostEngine)
 433 install(EXPORT GostProviderConfig DESTINATION GostEngine/share/cmake/GostProvider)