CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.18 FATAL_ERROR)
   2 project(gost-engine LANGUAGES C)
   3
   4 include(GNUInstallDirs)
   5 include(CheckLibraryExists)
   6 include(CheckFunctionExists)
   7 include(CheckCSourceRuns)
   8
   9 enable_testing()
  10
  11 find_package(OpenSSL 3.0 REQUIRED)
  12
  13 if (NOT DEFINED OPENSSL_ROOT_DIR)
  14   get_filename_component(OPENSSL_ROOT_DIR ${OPENSSL_INCLUDE_DIR} DIRECTORY)
  15   message(STATUS "Setting OpenSSL root: ${OPENSSL_ROOT_DIR}")
  16 endif()
  17 find_program(OPENSSL_PROGRAM openssl
  18   PATHS ${OPENSSL_ROOT_DIR} PATH_SUFFIXES apps bin NO_DEFAULT_PATH)
  19 message(STATUS "Found OpenSSL application: ${OPENSSL_PROGRAM}")
  20 include_directories(${OPENSSL_INCLUDE_DIR})
  21 set(OPENSSL_MODULES_DIR ${CMAKE_INSTALL_LIBDIR}/ossl-modules)
  22
  23 if (CMAKE_C_COMPILER_ID MATCHES "Clang")
  24   set(CMAKE_C_FLAGS_RELEASE -O2)
  25   set(CMAKE_C_FLAGS_DEBUG "-O0 -ggdb")
  26   set(CMAKE_C_FLAGS_RELWITHDEBINFO "-O2 -ggdb")
  27   add_compile_options(-Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -Qunused-arguments -Wno-deprecated-declarations)
  28 elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
  29   set(CMAKE_C_FLAGS_RELEASE -O2)
  30   set(CMAKE_C_FLAGS_DEBUG "-O0 -ggdb")
  31   set(CMAKE_C_FLAGS_RELWITHDEBINFO "-O2 -ggdb")
  32   add_compile_options(-Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -Wno-error=unknown-pragmas -Wno-error=pragmas -Wno-deprecated-declarations)
  33 elseif(CMAKE_C_COMPILER_ID MATCHES "MSVC")
  34   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
  35   add_definitions(-D_CRT_DEPRECATED_NO_WARNINGS)
  36   add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
  37   add_compile_options(/MP /WX /W4 /wd4100 /wd4267 /wd4206 /wd4706 /wd4244 /wd4115 /wd4996)
  38 endif()
  39
  40 if (ASAN)
  41   message(STATUS "address sanitizer enabled")
  42   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=address -g3 -fno-omit-frame-pointer")
  43   set(SKIP_PERL_TESTS 1)
  44 endif()
  45
  46 set(CMAKE_C_STANDARD 90)
  47 CHECK_FUNCTION_EXISTS(clock_gettime HAVE_CLOCK_GETTIME_C)
  48 CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_CLOCK_GETTIME_RT)
  49 if(HAVE_CLOCK_GETTIME_RT AND NOT HAVE_CLOCK_GETTIME_C)
  50   set(CLOCK_GETTIME_LIB rt)
  51 endif()
  52
  53 include (TestBigEndian)
  54 TEST_BIG_ENDIAN(IS_BIG_ENDIAN)
  55 if(IS_BIG_ENDIAN)
  56  message(STATUS "BIG_ENDIAN")
  57 else()
  58  message(STATUS "LITTLE_ENDIAN")
  59  add_definitions(-DL_ENDIAN)
  60 endif()
  61
  62 check_c_source_runs("
  63   #ifdef _MSC_VER
  64   # include <intrin.h>
  65   #else
  66   # include <x86intrin.h>
  67   #endif
  68   int main(void) {
  69     unsigned long long x = -1, y = 1, r;
  70     unsigned char cf;
  71     cf = _addcarry_u64(1, x, y, &r);
  72     return !(cf == 1 && r == 1);
  73   }
  74   " ADDCARRY_U64)
  75 if (ADDCARRY_U64)
  76   add_definitions(-DHAVE_ADDCARRY_U64)
  77 endif()
  78
  79 check_c_source_runs("
  80   int main(void) {
  81     char buf[16] = { 0, 1, 2 };
  82     int *p = (int *)(buf + 1);
  83     int *q = (int *)(buf + 2);
  84     return (*p == *q);
  85   }
  86   " RELAXED_ALIGNMENT)
  87 if (NOT RELAXED_ALIGNMENT)
  88   add_definitions(-DSTRICT_ALIGNMENT)
  89 endif()
  90
  91 set(BIN_DIRECTORY bin)
  92
  93 set(OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${BIN_DIRECTORY})
  94
  95 #set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  96 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  97 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  98
  99 # Remove when https://gitlab.kitware.com/cmake/cmake/issues/18525 is addressed
 100 set(OPENSSL_ENGINES_DIR "" CACHE PATH "OpenSSL Engines Directory")
 101 if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
 102         include(FindPkgConfig)
 103         pkg_get_variable(OPENSSL_ENGINES_DIR libcrypto enginesdir)
 104         if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
 105                 message( FATAL_ERROR "Unable to discover the OpenSSL engines directory. Provide the path using -DOPENSSL_ENGINES_DIR" )
 106         endif()
 107 endif()
 108
 109 set(GOST_89_SOURCE_FILES
 110         gost89.c
 111         gost89.h
 112         )
 113
 114 set(GOST_HASH_SOURCE_FILES
 115         gosthash.c
 116         gosthash.h
 117         )
 118
 119 set(GOST_HASH_2012_SOURCE_FILES
 120         gosthash2012.c
 121         gosthash2012.h
 122         gosthash2012_const.h
 123         gosthash2012_precalc.h
 124         gosthash2012_ref.h
 125         gosthash2012_sse2.h
 126         )
 127
 128 set(GOST_GRASSHOPPER_SOURCE_FILES
 129         gost_grasshopper.h
 130         gost_grasshopper_core.h
 131         gost_grasshopper_core.c
 132         gost_grasshopper_defines.h
 133         gost_grasshopper_defines.c
 134         gost_grasshopper_math.h
 135         gost_grasshopper_galois_precompiled.c
 136         gost_grasshopper_precompiled.c
 137         gost_grasshopper_cipher.h
 138         gost_grasshopper_cipher.c
 139         )
 140
 141 set(GOST_ERR_SOURCE_FILES
 142         e_gost_err.c
 143         e_gost_err.h
 144         )
 145
 146 set(GOST_CORE_SOURCE_FILES
 147         gost_ameth.c
 148         gost_pmeth.c
 149         gost_ctl.c
 150         gost_asn1.c
 151         gost_crypt.c
 152         gost_keywrap.c
 153         gost_keywrap.h
 154         gost_md.c
 155         gost_md2012.c
 156         gost_omac.c
 157         gost_omac_acpkm.c
 158         gost_gost2015.c
 159         gost_lcl.h
 160         gost_params.c
 161         gost_keyexpimp.c
 162         )
 163
 164 set(GOST_EC_SOURCE_FILES
 165         gost_ec_keyx.c
 166         gost_ec_sign.c
 167         ecp_id_GostR3410_2001_CryptoPro_A_ParamSet.c
 168         ecp_id_GostR3410_2001_CryptoPro_B_ParamSet.c
 169         ecp_id_GostR3410_2001_CryptoPro_C_ParamSet.c
 170         ecp_id_GostR3410_2001_TestParamSet.c
 171         ecp_id_tc26_gost_3410_2012_256_paramSetA.c
 172         ecp_id_tc26_gost_3410_2012_512_paramSetA.c
 173         ecp_id_tc26_gost_3410_2012_512_paramSetB.c
 174         ecp_id_tc26_gost_3410_2012_512_paramSetC.c
 175         )
 176
 177 set (GOST_OMAC_SOURCE_FILES
 178         gost_omac.c
 179         gost_omac_acpkm.c
 180         )
 181
 182 set(GOST_LIB_SOURCE_FILES
 183         ${GOST_CORE_SOURCE_FILES}
 184         ${GOST_89_SOURCE_FILES}
 185         ${GOST_HASH_SOURCE_FILES}
 186         ${GOST_HASH_2012_SOURCE_FILES}
 187         ${GOST_GRASSHOPPER_SOURCE_FILES}
 188         ${GOST_EC_SOURCE_FILES}
 189         ${GOST_OMAC_SOURCE_FILES}
 190         )
 191
 192 set(GOST_ENGINE_SOURCE_FILES
 193         gost_eng.c
 194         )
 195
 196 set(GOST_PROV_SOURCE_FILES
 197         gost_prov.c
 198         gost_prov_cipher.c
 199         gost_prov_digest.c
 200         gost_prov_mac.c
 201         )
 202
 203 set(TEST_ENVIRONMENT_COMMON
 204         CMAKE_CURRENT_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}
 205         PERL5LIB=${CMAKE_CURRENT_SOURCE_DIR}/test
 206         OPENSSL_PROGRAM=${OPENSSL_PROGRAM}
 207         OPENSSL_CRYPTO_LIBRARY=${OPENSSL_CRYPTO_LIBRARY}
 208         )
 209
 210 set(TEST_ENVIRONMENT_ENGINE
 211         ${TEST_ENVIRONMENT_COMMON}
 212         OPENSSL_ENGINES=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 213         OPENSSL_CONF=${CMAKE_CURRENT_SOURCE_DIR}/test/engine.cnf
 214         )
 215
 216 set(TEST_ENVIRONMENT_PROVIDER
 217         ${TEST_ENVIRONMENT_COMMON}
 218         OPENSSL_MODULES=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 219         OPENSSL_CONF=${CMAKE_CURRENT_SOURCE_DIR}/test/provider.cnf
 220         )
 221
 222 add_executable(test_digest test_digest.c)
 223 target_link_libraries(test_digest OpenSSL::Crypto)
 224 add_test(NAME digest-with-engine COMMAND test_digest)
 225 set_tests_properties(digest-with-engine
 226   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 227 add_test(NAME digest-with-provider COMMAND test_digest)
 228 set_tests_properties(digest-with-provider
 229   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 230
 231 add_executable(test_ciphers test_ciphers.c)
 232 target_link_libraries(test_ciphers OpenSSL::Crypto)
 233 add_test(NAME ciphers-with-engine COMMAND test_ciphers)
 234 set_tests_properties(ciphers-with-engine
 235   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 236 add_test(NAME ciphers-with-provider COMMAND test_ciphers)
 237 set_tests_properties(ciphers-with-provider
 238   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 239
 240 # test_curves is an internals testing program, it doesn't need a test env
 241 add_executable(test_curves test_curves.c)
 242 target_link_libraries(test_curves gost_core gost_err)
 243 add_test(NAME curves COMMAND test_curves)
 244
 245 add_executable(test_params test_params.c)
 246 target_link_libraries(test_params OpenSSL::Crypto)
 247 add_test(NAME parameters-with-engine COMMAND test_params)
 248 set_tests_properties(parameters-with-engine
 249   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 250
 251 add_executable(test_derive test_derive.c)
 252 target_link_libraries(test_derive OpenSSL::Crypto)
 253 add_test(NAME derive-with-engine COMMAND test_derive)
 254 set_tests_properties(derive-with-engine
 255   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 256
 257 add_executable(test_sign test_sign.c)
 258 target_link_libraries(test_sign OpenSSL::Crypto)
 259 add_test(NAME sign/verify-with-engine COMMAND test_sign)
 260 set_tests_properties(sign/verify-with-engine
 261   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 262
 263 if(NOT MSVC)
 264   add_executable(test_tls test_tls.c)
 265   target_link_libraries(test_tls OpenSSL::SSL)
 266   add_test(NAME TLS-with-engine COMMAND test_tls)
 267   set_tests_properties(TLS-with-engine
 268     PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 269 endif()
 270
 271 add_executable(test_context test_context.c)
 272 target_link_libraries(test_context OpenSSL::Crypto)
 273 add_test(NAME context-with-engine COMMAND test_context)
 274 set_tests_properties(context-with-engine
 275   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 276 add_test(NAME context-with-provider COMMAND test_context)
 277 set_tests_properties(context-with-provider
 278   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 279
 280 # test_keyexpimp is an internals testing program, it doesn't need a test env
 281 add_executable(test_keyexpimp test_keyexpimp.c)
 282 #target_compile_definitions(test_keyexpimp PUBLIC -DOPENSSL_LOAD_CONF)
 283 target_link_libraries(test_keyexpimp gost_core gost_err)
 284 add_test(NAME keyexpimp COMMAND test_keyexpimp)
 285
 286 # test_gost89 is an internals testing program, it doesn't need a test env
 287 add_executable(test_gost89 test_gost89.c)
 288 target_link_libraries(test_gost89 gost_core gost_err)
 289 add_test(NAME gost89 COMMAND test_gost89)
 290
 291 if(NOT SKIP_PERL_TESTS)
 292     execute_process(COMMAND perl -MTest2::V0 -e ""
 293        ERROR_QUIET RESULT_VARIABLE MISSING_TEST2_V0)
 294     find_program(HAVE_PROVE NAMES prove)
 295     if(NOT MISSING_TEST2_V0 AND HAVE_PROVE)
 296         add_test(NAME engine
 297             COMMAND prove --merge -PWrapOpenSSL ${CMAKE_CURRENT_SOURCE_DIR}/test :: engine)
 298         set_tests_properties(engine PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 299         add_test(NAME provider
 300             COMMAND prove --merge -PWrapOpenSSL ${CMAKE_CURRENT_SOURCE_DIR}/test :: provider)
 301         set_tests_properties(provider PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 302     else()
 303         message(STATUS "No Test2::V0 perl module (engine and provider tests skipped)")
 304     endif()
 305 endif()
 306
 307 if(NOT MSVC)
 308   add_executable(sign benchmark/sign.c)
 309   target_link_libraries(sign gost_core gost_err ${CLOCK_GETTIME_LIB})
 310 endif()
 311
 312 # All that may need to load just built engine will have path to it defined.
 313 set(BINARY_TESTS_TARGETS
 314         test_digest
 315         test_ciphers
 316         test_curves
 317         test_params
 318         test_derive
 319         test_sign
 320         test_context
 321         test_keyexpimp
 322         test_gost89
 323         )
 324 if(NOT MSVC)
 325   list(APPEND BINARY_TESTS_TARGETS test_tls)
 326 endif()
 327 set_property(TARGET ${BINARY_TESTS_TARGETS} APPEND PROPERTY COMPILE_DEFINITIONS ENGINE_DIR="${OUTPUT_DIRECTORY}")
 328
 329 add_library(gost_core STATIC ${GOST_LIB_SOURCE_FILES})
 330 set_target_properties(gost_core PROPERTIES POSITION_INDEPENDENT_CODE ON)
 331 target_link_libraries(gost_core PRIVATE OpenSSL::Crypto)
 332 add_library(gost_err STATIC ${GOST_ERR_SOURCE_FILES})
 333 set_target_properties(gost_err PROPERTIES POSITION_INDEPENDENT_CODE ON)
 334 target_link_libraries(gost_err PRIVATE OpenSSL::Crypto)
 335
 336 # The GOST engine in module form
 337 add_library(gost_engine MODULE ${GOST_ENGINE_SOURCE_FILES})
 338 # Set the suffix explicitly to adapt to OpenSSL's idea of what a
 339 # module suffix should be
 340 set_target_properties(gost_engine PROPERTIES
 341   PREFIX "" OUTPUT_NAME "gost" SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX})
 342 target_link_libraries(gost_engine PRIVATE gost_core gost_err)
 343
 344 if (NOT MSVC)
 345 # The GOST engine in library form
 346 add_library(lib_gost_engine SHARED ${GOST_ENGINE_SOURCE_FILES})
 347 set_target_properties(lib_gost_engine PROPERTIES
 348   COMPILE_DEFINITIONS "BUILDING_ENGINE_AS_LIBRARY"
 349   PUBLIC_HEADER gost-engine.h
 350   OUTPUT_NAME "gost")
 351 target_link_libraries(lib_gost_engine PRIVATE gost_core gost_err)
 352 endif()
 353
 354 # The GOST provider uses this
 355 add_subdirectory(libprov)
 356
 357 # The GOST provider in module form
 358 add_library(gost_prov MODULE
 359   ${GOST_PROV_SOURCE_FILES} ${GOST_ENGINE_SOURCE_FILES}
 360   )
 361 set_target_properties(gost_prov PROPERTIES
 362   PREFIX "" OUTPUT_NAME "gostprov" SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX}
 363   COMPILE_DEFINITIONS "BUILDING_GOST_PROVIDER;OPENSSL_NO_DYNAMIC_ENGINE"
 364   )
 365 target_link_libraries(gost_prov PRIVATE gost_core libprov)
 366
 367 if (NOT MSVC)
 368 # The GOST provider in library form
 369 add_library(lib_gost_prov SHARED
 370   ${GOST_PROV_SOURCE_FILES} ${GOST_ENGINE_SOURCE_FILES}
 371   )
 372 set_target_properties(lib_gost_prov PROPERTIES
 373   OUTPUT_NAME "gostprov"
 374   COMPILE_DEFINITIONS "BUILDING_GOST_PROVIDER;BUILDING_PROVIDER_AS_LIBRARY;OPENSSL_NO_DYNAMIC_ENGINE"
 375   )
 376 target_link_libraries(lib_gost_prov PRIVATE gost_core libprov)
 377 endif()
 378
 379 set(GOST_SUM_SOURCE_FILES
 380         gostsum.c
 381         )
 382
 383 add_executable(gostsum ${GOST_SUM_SOURCE_FILES})
 384 target_link_libraries(gostsum gost_core gost_err)
 385
 386 set(GOST_12_SUM_SOURCE_FILES
 387         gost12sum.c
 388         )
 389
 390 add_executable(gost12sum ${GOST_12_SUM_SOURCE_FILES})
 391 target_link_libraries(gost12sum gost_core gost_err)
 392
 393 set_source_files_properties(tags PROPERTIES GENERATED true)
 394 add_custom_target(tags
 395     COMMAND ctags -R . ${OPENSSL_ROOT_DIR}
 396     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 397
 398 add_custom_target(tcl_tests
 399     COMMAND OPENSSL_LIBCRYPTO=${OPENSSL_CRYPTO_LIBRARY}
 400             OPENSSL_APP=${OPENSSL_PROGRAM}
 401             TESTSRC=${CMAKE_SOURCE_DIR}/tcl_tests
 402             TESTDIR=${CMAKE_BINARY_DIR}/tcl_tests
 403             ENGINE_DIR=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 404             sh ./runtest.sh
 405     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/tcl_tests)
 406
 407 add_executable(test_tlstree test_tlstree.c)
 408 target_link_libraries(test_tlstree PUBLIC OpenSSL::Crypto)
 409
 410 # install programs and manuals
 411 install(TARGETS gostsum gost12sum RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 412 install(FILES gostsum.1 gost12sum.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)
 413
 414 # install engine and provider in module form
 415 install(TARGETS gost_engine EXPORT GostEngineConfig
 416         LIBRARY  DESTINATION ${OPENSSL_ENGINES_DIR}
 417         RUNTIME  DESTINATION ${OPENSSL_ENGINES_DIR})
 418 install(TARGETS gost_prov EXPORT GostProviderConfig
 419         LIBRARY  DESTINATION ${OPENSSL_MODULES_DIR}
 420         RUNTIME  DESTINATION ${OPENSSL_MODULES_DIR})
 421 if (NOT MSVC)
 422 # install engine and provider in library form
 423 install(TARGETS lib_gost_engine EXPORT GostEngineConfig
 424         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 425 install(TARGETS lib_gost_prov EXPORT GostProviderConfig
 426         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 427 endif()
 428
 429 if (MSVC)
 430   install(FILES $<TARGET_PDB_FILE:gostsum> $<TARGET_PDB_FILE:gost12sum>
 431     EXPORT GostEngineConfig DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 432   install(FILES $<TARGET_PDB_FILE:gost_engine>
 433     EXPORT GostEngineConfig DESTINATION ${OPENSSL_ENGINES_DIR} OPTIONAL)
 434   install(FILES $<TARGET_PDB_FILE:gost_prov>
 435     EXPORT GostProviderConfig DESTINATION ${OPENSSL_MODULES_DIR} OPTIONAL)
 436 endif()
 437 install(EXPORT GostEngineConfig DESTINATION GostEngine/share/cmake/GostEngine)
 438 install(EXPORT GostProviderConfig DESTINATION GostEngine/share/cmake/GostProvider)