CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
   2 project(gost-engine LANGUAGES C)
   3
   4 include(GNUInstallDirs)
   5 include(CheckLibraryExists)
   6 include(CheckFunctionExists)
   7
   8 enable_testing()
   9
  10 find_package(OpenSSL 1.1.1 REQUIRED)
  11 include_directories(${OPENSSL_INCLUDE_DIR})
  12
  13 if (CMAKE_C_COMPILER_ID MATCHES "Clang")
  14  add_compile_options(-O2 -Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -ggdb -Qunused-arguments)
  15 elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
  16  add_compile_options(-O2 -Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -ggdb)
  17 elseif(CMAKE_C_COMPILER_ID MATCHES "MSVC")
  18  add_definitions(-D_CRT_SECURE_NO_WARNINGS)
  19  add_definitions(-D_CRT_DEPRECATED_NO_WARNINGS)
  20  add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
  21  add_compile_options(/MP /WX /W4 /wd4100 /wd4267 /wd4206 /wd4706 /wd4244 /wd4115)
  22 endif()
  23
  24 if (ASAN)
  25   message(STATUS "address sanitizer enabled")
  26   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=address -g3 -fno-omit-frame-pointer")
  27 endif()
  28
  29 # DEPRECATEDIN_3_0 CMAC
  30 set_source_files_properties(gost_omac.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  31 # DEPRECATEDIN_3_0 HMAC
  32 set_source_files_properties(gost_keyexpimp.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  33
  34 set(CMAKE_C_STANDARD 90)
  35 CHECK_FUNCTION_EXISTS(clock_gettime HAVE_CLOCK_GETTIME_C)
  36 CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_CLOCK_GETTIME_RT)
  37 if(HAVE_CLOCK_GETTIME_RT AND NOT HAVE_CLOCK_GETTIME_C)
  38   set(CLOCK_GETTIME_LIB rt)
  39 endif()
  40
  41 include (TestBigEndian)
  42 TEST_BIG_ENDIAN(IS_BIG_ENDIAN)
  43 if(IS_BIG_ENDIAN)
  44  message(STATUS "BIG_ENDIAN")
  45 else()
  46  message(STATUS "LITTLE_ENDIAN")
  47  add_definitions(-DL_ENDIAN)
  48 endif()
  49
  50 set(BIN_DIRECTORY bin)
  51
  52 # Same soversion as OpenSSL
  53 set(GOST_SOVERSION "${OPENSSL_VERSION_MAJOR}.${OPENSSL_VERSION_MINOR}")
  54
  55 set(OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${BIN_DIRECTORY})
  56
  57 #set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  58 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  59 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  60
  61 # Remove when https://gitlab.kitware.com/cmake/cmake/issues/18525 is addressed
  62 set(OPENSSL_ENGINES_DIR "" CACHE PATH "OpenSSL Engines Directory")
  63 if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
  64         include(FindPkgConfig)
  65         pkg_get_variable(OPENSSL_ENGINES_DIR libcrypto enginesdir)
  66         if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
  67                 message( FATAL_ERROR "Unable to discover the OpenSSL engines directory. Provide the path using -DOPENSSL_ENGINES_DIR" )
  68         endif()
  69 endif()
  70
  71 set(GOST_89_SOURCE_FILES
  72         gost89.c
  73         gost89.h
  74         )
  75
  76 set(GOST_HASH_SOURCE_FILES
  77         gosthash.c
  78         gosthash.h
  79         )
  80
  81 set(GOST_HASH_2012_SOURCE_FILES
  82         gosthash2012.c
  83         gosthash2012.h
  84         gosthash2012_const.h
  85         gosthash2012_precalc.h
  86         gosthash2012_ref.h
  87         gosthash2012_sse2.h
  88         )
  89
  90 set(GOST_GRASSHOPPER_SOURCE_FILES
  91         gost_grasshopper.h
  92         gost_grasshopper_core.h
  93         gost_grasshopper_core.c
  94         gost_grasshopper_defines.h
  95         gost_grasshopper_defines.c
  96         gost_grasshopper_math.h
  97         gost_grasshopper_galois_precompiled.c
  98         gost_grasshopper_precompiled.c
  99         gost_grasshopper_cipher.h
 100         gost_grasshopper_cipher.c
 101         )
 102
 103 set(GOST_CORE_SOURCE_FILES
 104         e_gost_err.c
 105         e_gost_err.h
 106         gost_asn1.c
 107         gost_crypt.c
 108         gost_ctl.c
 109         gost_eng.c
 110         gost_keywrap.c
 111         gost_keywrap.h
 112         gost_lcl.h
 113         gost_params.c
 114         gost_keyexpimp.c
 115         )
 116
 117 set(GOST_EC_SOURCE_FILES
 118         gost_ec_keyx.c
 119         gost_ec_sign.c
 120         )
 121
 122 set (GOST_OMAC_SOURCE_FILES
 123         gost_omac.c
 124         gost_omac_acpkm.c
 125         )
 126
 127 set(GOST_LIB_SOURCE_FILES
 128         ${GOST_89_SOURCE_FILES}
 129         ${GOST_HASH_SOURCE_FILES}
 130         ${GOST_HASH_2012_SOURCE_FILES}
 131         ${GOST_GRASSHOPPER_SOURCE_FILES}
 132         ${GOST_EC_SOURCE_FILES}
 133         ${GOST_OMAC_SOURCE_FILES}
 134         )
 135
 136 set(GOST_ENGINE_SOURCE_FILES
 137         ${GOST_CORE_SOURCE_FILES}
 138         gost_ameth.c
 139         gost_md.c
 140         gost_md2012.c
 141         gost_pmeth.c
 142         gost_omac.c
 143         gost_omac_acpkm.c
 144         )
 145
 146 add_executable(test_digest test_digest.c)
 147 target_link_libraries(test_digest gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 148 add_test(NAME digest
 149         COMMAND test_digest)
 150
 151 add_executable(test_curves test_curves.c)
 152 target_link_libraries(test_curves gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 153 add_test(NAME curves
 154         COMMAND test_curves)
 155
 156 add_executable(test_params test_params.c)
 157 target_link_libraries(test_params gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 158 add_test(NAME parameters
 159         COMMAND test_params)
 160
 161 add_executable(test_sign test_sign.c)
 162 target_link_libraries(test_sign gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 163 add_test(NAME sign/verify
 164         COMMAND test_sign)
 165
 166 add_executable(test_tls test_tls.c)
 167 target_link_libraries(test_tls gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY} ${OPENSSL_SSL_LIBRARY})
 168 add_test(NAME TLS
 169         COMMAND test_tls)
 170
 171 add_executable(test_context test_context.c)
 172 target_link_libraries(test_context gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 173 add_test(NAME context
 174         COMMAND test_context)
 175
 176 add_executable(test_grasshopper test_grasshopper.c)
 177 target_link_libraries(test_grasshopper gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 178 add_test(NAME grasshopper
 179         COMMAND test_grasshopper)
 180
 181 add_executable(test_keyexpimp test_keyexpimp.c)
 182 #target_compile_definitions(test_keyexpimp PUBLIC -DOPENSSL_LOAD_CONF)
 183 target_link_libraries(test_keyexpimp gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 184 add_test(NAME keyexpimp
 185         COMMAND test_keyexpimp)
 186
 187 add_executable(test_gost89 test_gost89.c)
 188 target_link_libraries(test_gost89 gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 189 add_test(NAME gost89
 190         COMMAND test_gost89)
 191
 192 if(NOT ASAN)
 193 add_test(NAME engine
 194         COMMAND perl run_tests
 195         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/test)
 196 set_tests_properties(engine PROPERTIES ENVIRONMENT
 197         "OPENSSL_ROOT_DIR=${OPENSSL_ROOT_DIR};OPENSSL_ENGINES=${OUTPUT_DIRECTORY};OPENSSL_CONF=${CMAKE_SOURCE_DIR}/test/empty.cnf")
 198 endif()
 199
 200 add_executable(sign benchmark/sign.c)
 201 target_link_libraries(sign gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY} ${CLOCK_GETTIME_LIB})
 202
 203 # All that may need to load just built engine will have path to it defined.
 204 set(BINARY_TESTS_TARGETS
 205         test_digest
 206         test_curves
 207         test_params
 208         test_sign
 209         test_context
 210         test_grasshopper
 211         test_keyexpimp
 212         test_gost89
 213         test_tls
 214         )
 215 set_property(TARGET ${BINARY_TESTS_TARGETS} APPEND PROPERTY COMPILE_DEFINITIONS ENGINE_DIR="${OUTPUT_DIRECTORY}")
 216
 217 add_library(gost_core STATIC ${GOST_LIB_SOURCE_FILES})
 218 set_target_properties(gost_core PROPERTIES POSITION_INDEPENDENT_CODE ON)
 219
 220 add_library(gost_engine SHARED ${GOST_ENGINE_SOURCE_FILES})
 221 set_target_properties(gost_engine PROPERTIES PREFIX "" OUTPUT_NAME "gost")
 222 set_target_properties(gost_engine PROPERTIES VERSION ${GOST_SOVERSION} SOVERSION ${GOST_SOVERSION})
 223 target_link_libraries(gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 224
 225 set(GOST_SUM_SOURCE_FILES
 226         gostsum.c
 227         )
 228
 229 add_executable(gostsum ${GOST_SUM_SOURCE_FILES})
 230 target_link_libraries(gostsum gost_core)
 231
 232 set(GOST_12_SUM_SOURCE_FILES
 233         gost12sum.c
 234         )
 235
 236 add_executable(gost12sum ${GOST_12_SUM_SOURCE_FILES})
 237 target_link_libraries(gost12sum gost_core)
 238
 239 set_source_files_properties(tags PROPERTIES GENERATED true)
 240 add_custom_target(tags
 241     COMMAND ctags -R . ${OPENSSL_ROOT_DIR}
 242     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 243
 244 add_custom_target(tcl_tests
 245     COMMAND ENGINE_DIR=${OUTPUT_DIRECTORY} sh ./runtest.sh
 246     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/tcl_tests)
 247
 248 add_executable(test_tlstree test_tlstree.c)
 249 target_link_libraries(test_tlstree PUBLIC ${OPENSSL_CRYPTO_LIBRARY})
 250
 251 # install
 252 set(OPENSSL_MAN_INSTALL_DIR ${CMAKE_INSTALL_MANDIR}/man1)
 253
 254 install(TARGETS gost_engine gostsum gost12sum EXPORT GostEngineConfig
 255         LIBRARY  DESTINATION ${OPENSSL_ENGINES_DIR}
 256         RUNTIME  DESTINATION ${CMAKE_INSTALL_BINDIR})
 257 install(FILES gostsum.1 gost12sum.1 DESTINATION ${OPENSSL_MAN_INSTALL_DIR})
 258 if (MSVC)
 259  install(FILES $<TARGET_PDB_FILE:gost_engine> DESTINATION ${OPENSSL_ENGINES_DIR} OPTIONAL)
 260  install(FILES $<TARGET_PDB_FILE:gostsum> $<TARGET_PDB_FILE:gost12sum> DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 261 endif()