CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
   2 project(gost-engine LANGUAGES C)
   3
   4 include(GNUInstallDirs)
   5 include(CheckLibraryExists)
   6 include(CheckFunctionExists)
   7 include(CheckCSourceRuns)
   8
   9 enable_testing()
  10
  11 find_package(OpenSSL 1.1.1 REQUIRED)
  12 include_directories(${OPENSSL_INCLUDE_DIR})
  13
  14 if (CMAKE_C_COMPILER_ID MATCHES "Clang")
  15  add_compile_options(-O2 -Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -ggdb -Qunused-arguments)
  16 elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
  17  add_compile_options(-O2 -Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -ggdb -Wno-error=unknown-pragmas -Wno-deprecated-declarations)
  18 elseif(CMAKE_C_COMPILER_ID MATCHES "MSVC")
  19  add_definitions(-D_CRT_SECURE_NO_WARNINGS)
  20  add_definitions(-D_CRT_DEPRECATED_NO_WARNINGS)
  21  add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
  22  add_compile_options(/MP /WX /W4 /wd4100 /wd4267 /wd4206 /wd4706 /wd4244 /wd4115)
  23 endif()
  24
  25 if (ASAN)
  26   message(STATUS "address sanitizer enabled")
  27   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=address -g3 -fno-omit-frame-pointer")
  28   set(SKIP_PERL_TESTS 1)
  29 endif()
  30
  31 # DEPRECATEDIN_3_0 CMAC
  32 set_source_files_properties(gost_omac.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  33 # DEPRECATEDIN_3_0 HMAC
  34 set_source_files_properties(gost_keyexpimp.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  35
  36 set(CMAKE_C_STANDARD 90)
  37 CHECK_FUNCTION_EXISTS(clock_gettime HAVE_CLOCK_GETTIME_C)
  38 CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_CLOCK_GETTIME_RT)
  39 if(HAVE_CLOCK_GETTIME_RT AND NOT HAVE_CLOCK_GETTIME_C)
  40   set(CLOCK_GETTIME_LIB rt)
  41 endif()
  42
  43 include (TestBigEndian)
  44 TEST_BIG_ENDIAN(IS_BIG_ENDIAN)
  45 if(IS_BIG_ENDIAN)
  46  message(STATUS "BIG_ENDIAN")
  47 else()
  48  message(STATUS "LITTLE_ENDIAN")
  49  add_definitions(-DL_ENDIAN)
  50 endif()
  51
  52 check_c_source_runs("
  53   #ifdef _MSC_VER
  54   # include <intrin.h>
  55   #else
  56   # include <x86intrin.h>
  57   #endif
  58   int main(void) {
  59     unsigned long long x = -1, y = 1, r;
  60     unsigned char cf;
  61     cf = _addcarry_u64(1, x, y, &r);
  62     return !(cf == 1 && r == 1);
  63   }
  64   " ADDCARRY_U64)
  65 if (ADDCARRY_U64)
  66   add_definitions(-DHAVE_ADDCARRY_U64)
  67 endif()
  68
  69 set(BIN_DIRECTORY bin)
  70
  71 # Same soversion as OpenSSL
  72 set(GOST_SOVERSION "${OPENSSL_VERSION_MAJOR}.${OPENSSL_VERSION_MINOR}")
  73
  74 set(OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${BIN_DIRECTORY})
  75
  76 #set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  77 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  78 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  79
  80 # Remove when https://gitlab.kitware.com/cmake/cmake/issues/18525 is addressed
  81 set(OPENSSL_ENGINES_DIR "" CACHE PATH "OpenSSL Engines Directory")
  82 if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
  83         include(FindPkgConfig)
  84         pkg_get_variable(OPENSSL_ENGINES_DIR libcrypto enginesdir)
  85         if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
  86                 message( FATAL_ERROR "Unable to discover the OpenSSL engines directory. Provide the path using -DOPENSSL_ENGINES_DIR" )
  87         endif()
  88 endif()
  89
  90 set(GOST_89_SOURCE_FILES
  91         gost89.c
  92         gost89.h
  93         )
  94
  95 set(GOST_HASH_SOURCE_FILES
  96         gosthash.c
  97         gosthash.h
  98         )
  99
 100 set(GOST_HASH_2012_SOURCE_FILES
 101         gosthash2012.c
 102         gosthash2012.h
 103         gosthash2012_const.h
 104         gosthash2012_precalc.h
 105         gosthash2012_ref.h
 106         gosthash2012_sse2.h
 107         )
 108
 109 set(GOST_GRASSHOPPER_SOURCE_FILES
 110         gost_grasshopper.h
 111         gost_grasshopper_core.h
 112         gost_grasshopper_core.c
 113         gost_grasshopper_defines.h
 114         gost_grasshopper_defines.c
 115         gost_grasshopper_math.h
 116         gost_grasshopper_galois_precompiled.c
 117         gost_grasshopper_precompiled.c
 118         gost_grasshopper_cipher.h
 119         gost_grasshopper_cipher.c
 120         )
 121
 122 set(GOST_CORE_SOURCE_FILES
 123         e_gost_err.c
 124         e_gost_err.h
 125         gost_asn1.c
 126         gost_crypt.c
 127         gost_ctl.c
 128         gost_eng.c
 129         gost_keywrap.c
 130         gost_keywrap.h
 131         gost_lcl.h
 132         gost_params.c
 133         gost_keyexpimp.c
 134         )
 135
 136 set(GOST_EC_SOURCE_FILES
 137         gost_ec_keyx.c
 138         gost_ec_sign.c
 139         )
 140
 141 set (GOST_OMAC_SOURCE_FILES
 142         gost_omac.c
 143         gost_omac_acpkm.c
 144         )
 145
 146 set(GOST_LIB_SOURCE_FILES
 147         ${GOST_89_SOURCE_FILES}
 148         ${GOST_HASH_SOURCE_FILES}
 149         ${GOST_HASH_2012_SOURCE_FILES}
 150         ${GOST_GRASSHOPPER_SOURCE_FILES}
 151         ${GOST_EC_SOURCE_FILES}
 152         ${GOST_OMAC_SOURCE_FILES}
 153         )
 154
 155 set(GOST_ENGINE_SOURCE_FILES
 156         ${GOST_CORE_SOURCE_FILES}
 157         gost_ameth.c
 158         gost_md.c
 159         gost_md2012.c
 160         gost_pmeth.c
 161         gost_omac.c
 162         gost_omac_acpkm.c
 163         gost_gost2015.c
 164         )
 165
 166 add_executable(test_digest test_digest.c)
 167 target_link_libraries(test_digest gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 168 add_test(NAME digest
 169         COMMAND test_digest)
 170
 171 add_executable(test_curves test_curves.c)
 172 target_link_libraries(test_curves gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 173 add_test(NAME curves
 174         COMMAND test_curves)
 175
 176 add_executable(test_params test_params.c)
 177 target_link_libraries(test_params gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 178 add_test(NAME parameters
 179         COMMAND test_params)
 180
 181 add_executable(test_sign test_sign.c)
 182 target_link_libraries(test_sign gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 183 add_test(NAME sign/verify
 184         COMMAND test_sign)
 185
 186 add_executable(test_tls test_tls.c)
 187 target_link_libraries(test_tls gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY} ${OPENSSL_SSL_LIBRARY})
 188 add_test(NAME TLS
 189         COMMAND test_tls)
 190
 191 add_executable(test_context test_context.c)
 192 target_link_libraries(test_context gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 193 add_test(NAME context
 194         COMMAND test_context)
 195
 196 add_executable(test_grasshopper test_grasshopper.c)
 197 target_link_libraries(test_grasshopper gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 198 add_test(NAME grasshopper
 199         COMMAND test_grasshopper)
 200
 201 add_executable(test_keyexpimp test_keyexpimp.c)
 202 #target_compile_definitions(test_keyexpimp PUBLIC -DOPENSSL_LOAD_CONF)
 203 target_link_libraries(test_keyexpimp gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 204 add_test(NAME keyexpimp
 205         COMMAND test_keyexpimp)
 206
 207 add_executable(test_gost89 test_gost89.c)
 208 target_link_libraries(test_gost89 gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 209 add_test(NAME gost89
 210         COMMAND test_gost89)
 211
 212 if(NOT SKIP_PERL_TESTS)
 213     execute_process(COMMAND perl -MTest2::V0 -e ""
 214         ERROR_QUIET RESULT_VARIABLE HAVE_TEST2_V0)
 215     if(NOT HAVE_TEST2_V0)
 216         add_test(NAME engine
 217             COMMAND perl run_tests
 218             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/test)
 219         set_tests_properties(engine PROPERTIES ENVIRONMENT
 220             "OPENSSL_ROOT_DIR=${OPENSSL_ROOT_DIR};OPENSSL_ENGINES=${OUTPUT_DIRECTORY};OPENSSL_CONF=${CMAKE_SOURCE_DIR}/test/empty.cnf")
 221     else()
 222       message(STATUS "No Test2::V0 perl module (engine tests skipped)")
 223     endif()
 224 endif()
 225
 226 add_executable(sign benchmark/sign.c)
 227 target_link_libraries(sign gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY} ${CLOCK_GETTIME_LIB})
 228
 229 # All that may need to load just built engine will have path to it defined.
 230 set(BINARY_TESTS_TARGETS
 231         test_digest
 232         test_curves
 233         test_params
 234         test_sign
 235         test_context
 236         test_grasshopper
 237         test_keyexpimp
 238         test_gost89
 239         test_tls
 240         )
 241 set_property(TARGET ${BINARY_TESTS_TARGETS} APPEND PROPERTY COMPILE_DEFINITIONS ENGINE_DIR="${OUTPUT_DIRECTORY}")
 242
 243 add_library(gost_core STATIC ${GOST_LIB_SOURCE_FILES})
 244 set_target_properties(gost_core PROPERTIES POSITION_INDEPENDENT_CODE ON)
 245
 246 add_library(gost_engine SHARED ${GOST_ENGINE_SOURCE_FILES})
 247 set_target_properties(gost_engine PROPERTIES PREFIX "" OUTPUT_NAME "gost")
 248 set_target_properties(gost_engine PROPERTIES VERSION ${GOST_SOVERSION} SOVERSION ${GOST_SOVERSION})
 249 target_link_libraries(gost_engine gost_core ${OPENSSL_CRYPTO_LIBRARY})
 250
 251 set(GOST_SUM_SOURCE_FILES
 252         gostsum.c
 253         )
 254
 255 add_executable(gostsum ${GOST_SUM_SOURCE_FILES})
 256 target_link_libraries(gostsum gost_core ${OPENSSL_CRYPTO_LIBRARY})
 257
 258 set(GOST_12_SUM_SOURCE_FILES
 259         gost12sum.c
 260         )
 261
 262 add_executable(gost12sum ${GOST_12_SUM_SOURCE_FILES})
 263 target_link_libraries(gost12sum gost_core)
 264
 265 set_source_files_properties(tags PROPERTIES GENERATED true)
 266 add_custom_target(tags
 267     COMMAND ctags -R . ${OPENSSL_ROOT_DIR}
 268     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 269
 270 add_custom_target(tcl_tests
 271     COMMAND ENGINE_DIR=${OUTPUT_DIRECTORY} sh ./runtest.sh
 272     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/tcl_tests)
 273
 274 add_executable(test_tlstree test_tlstree.c)
 275 target_link_libraries(test_tlstree PUBLIC ${OPENSSL_CRYPTO_LIBRARY})
 276
 277 # install
 278 set(OPENSSL_MAN_INSTALL_DIR ${CMAKE_INSTALL_MANDIR}/man1)
 279
 280 install(TARGETS gost_engine gostsum gost12sum EXPORT GostEngineConfig
 281         LIBRARY  DESTINATION ${OPENSSL_ENGINES_DIR}
 282         RUNTIME  DESTINATION ${CMAKE_INSTALL_BINDIR})
 283 install(FILES gostsum.1 gost12sum.1 DESTINATION ${OPENSSL_MAN_INSTALL_DIR})
 284 if (MSVC)
 285  install(FILES $<TARGET_PDB_FILE:gost_engine> DESTINATION ${OPENSSL_ENGINES_DIR} OPTIONAL)
 286  install(FILES $<TARGET_PDB_FILE:gostsum> $<TARGET_PDB_FILE:gost12sum> DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 287 endif()