CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.18 FATAL_ERROR)
   2 project(gost-engine LANGUAGES C)
   3
   4 include(GNUInstallDirs)
   5 include(CheckLibraryExists)
   6 include(CheckFunctionExists)
   7 include(CheckCSourceRuns)
   8
   9 enable_testing()
  10
  11 find_package(OpenSSL 3.0 REQUIRED)
  12
  13 if (NOT DEFINED OPENSSL_ROOT_DIR)
  14   get_filename_component(OPENSSL_ROOT_DIR ${OPENSSL_INCLUDE_DIR} DIRECTORY)
  15   message(STATUS "Setting OpenSSL root: ${OPENSSL_ROOT_DIR}")
  16 endif()
  17 find_program(OPENSSL_PROGRAM openssl
  18   PATHS ${OPENSSL_ROOT_DIR} PATH_SUFFIXES apps bin NO_DEFAULT_PATH)
  19 message(STATUS "Found OpenSSL application: ${OPENSSL_PROGRAM}")
  20 include_directories(${OPENSSL_INCLUDE_DIR})
  21
  22 if (CMAKE_C_COMPILER_ID MATCHES "Clang")
  23   set(CMAKE_C_FLAGS_RELEASE -O2)
  24   set(CMAKE_C_FLAGS_DEBUG "-O0 -ggdb")
  25   set(CMAKE_C_FLAGS_RELWITHDEBINFO "-O2 -ggdb")
  26   add_compile_options(-Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -Qunused-arguments -Wno-deprecated-declarations)
  27 elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
  28   set(CMAKE_C_FLAGS_RELEASE -O2)
  29   set(CMAKE_C_FLAGS_DEBUG "-O0 -ggdb")
  30   set(CMAKE_C_FLAGS_RELWITHDEBINFO "-O2 -ggdb")
  31   add_compile_options(-Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -Wno-error=unknown-pragmas -Wno-error=pragmas -Wno-deprecated-declarations)
  32 elseif(CMAKE_C_COMPILER_ID MATCHES "MSVC")
  33   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
  34   add_definitions(-D_CRT_DEPRECATED_NO_WARNINGS)
  35   add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
  36   add_compile_options(/MP /WX /W4 /wd4100 /wd4267 /wd4206 /wd4706 /wd4244 /wd4115)
  37 endif()
  38
  39 if (ASAN)
  40   message(STATUS "address sanitizer enabled")
  41   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=address -g3 -fno-omit-frame-pointer")
  42   set(SKIP_PERL_TESTS 1)
  43 endif()
  44
  45 # DEPRECATEDIN_3_0 CMAC
  46 set_source_files_properties(gost_omac.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  47 # DEPRECATEDIN_3_0 HMAC
  48 set_source_files_properties(gost_keyexpimp.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  49
  50 set(CMAKE_C_STANDARD 90)
  51 CHECK_FUNCTION_EXISTS(clock_gettime HAVE_CLOCK_GETTIME_C)
  52 CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_CLOCK_GETTIME_RT)
  53 if(HAVE_CLOCK_GETTIME_RT AND NOT HAVE_CLOCK_GETTIME_C)
  54   set(CLOCK_GETTIME_LIB rt)
  55 endif()
  56
  57 include (TestBigEndian)
  58 TEST_BIG_ENDIAN(IS_BIG_ENDIAN)
  59 if(IS_BIG_ENDIAN)
  60  message(STATUS "BIG_ENDIAN")
  61 else()
  62  message(STATUS "LITTLE_ENDIAN")
  63  add_definitions(-DL_ENDIAN)
  64 endif()
  65
  66 check_c_source_runs("
  67   #ifdef _MSC_VER
  68   # include <intrin.h>
  69   #else
  70   # include <x86intrin.h>
  71   #endif
  72   int main(void) {
  73     unsigned long long x = -1, y = 1, r;
  74     unsigned char cf;
  75     cf = _addcarry_u64(1, x, y, &r);
  76     return !(cf == 1 && r == 1);
  77   }
  78   " ADDCARRY_U64)
  79 if (ADDCARRY_U64)
  80   add_definitions(-DHAVE_ADDCARRY_U64)
  81 endif()
  82
  83 check_c_source_runs("
  84   int main(void) {
  85     char buf[16] = { 0, 1, 2 };
  86     int *p = (int *)(buf + 1);
  87     int *q = (int *)(buf + 2);
  88     return (*p == *q);
  89   }
  90   " RELAXED_ALIGNMENT)
  91 if (NOT RELAXED_ALIGNMENT)
  92   add_definitions(-DSTRICT_ALIGNMENT)
  93 endif()
  94
  95 set(BIN_DIRECTORY bin)
  96
  97 set(OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${BIN_DIRECTORY})
  98
  99 #set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 100 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 101 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 102
 103 # Remove when https://gitlab.kitware.com/cmake/cmake/issues/18525 is addressed
 104 set(OPENSSL_ENGINES_DIR "" CACHE PATH "OpenSSL Engines Directory")
 105 if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
 106         include(FindPkgConfig)
 107         pkg_get_variable(OPENSSL_ENGINES_DIR libcrypto enginesdir)
 108         if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
 109                 message( FATAL_ERROR "Unable to discover the OpenSSL engines directory. Provide the path using -DOPENSSL_ENGINES_DIR" )
 110         endif()
 111 endif()
 112
 113 set(GOST_89_SOURCE_FILES
 114         gost89.c
 115         gost89.h
 116         )
 117
 118 set(GOST_HASH_SOURCE_FILES
 119         gosthash.c
 120         gosthash.h
 121         )
 122
 123 set(GOST_HASH_2012_SOURCE_FILES
 124         gosthash2012.c
 125         gosthash2012.h
 126         gosthash2012_const.h
 127         gosthash2012_precalc.h
 128         gosthash2012_ref.h
 129         gosthash2012_sse2.h
 130         )
 131
 132 set(GOST_GRASSHOPPER_SOURCE_FILES
 133         gost_grasshopper.h
 134         gost_grasshopper_core.h
 135         gost_grasshopper_core.c
 136         gost_grasshopper_defines.h
 137         gost_grasshopper_defines.c
 138         gost_grasshopper_math.h
 139         gost_grasshopper_galois_precompiled.c
 140         gost_grasshopper_precompiled.c
 141         gost_grasshopper_cipher.h
 142         gost_grasshopper_cipher.c
 143         )
 144
 145 set(GOST_ERR_SOURCE_FILES
 146         e_gost_err.c
 147         e_gost_err.h
 148         )
 149
 150 set(GOST_CORE_SOURCE_FILES
 151         gost_ameth.c
 152         gost_pmeth.c
 153         gost_ctl.c
 154         gost_asn1.c
 155         gost_crypt.c
 156         gost_keywrap.c
 157         gost_keywrap.h
 158         gost_md.c
 159         gost_md2012.c
 160         gost_omac.c
 161         gost_omac_acpkm.c
 162         gost_gost2015.c
 163         gost_lcl.h
 164         gost_params.c
 165         gost_keyexpimp.c
 166         )
 167
 168 set(GOST_EC_SOURCE_FILES
 169         gost_ec_keyx.c
 170         gost_ec_sign.c
 171         ecp_id_GostR3410_2001_CryptoPro_A_ParamSet.c
 172         ecp_id_GostR3410_2001_CryptoPro_B_ParamSet.c
 173         ecp_id_GostR3410_2001_CryptoPro_C_ParamSet.c
 174         ecp_id_GostR3410_2001_TestParamSet.c
 175         ecp_id_tc26_gost_3410_2012_256_paramSetA.c
 176         ecp_id_tc26_gost_3410_2012_512_paramSetA.c
 177         ecp_id_tc26_gost_3410_2012_512_paramSetB.c
 178         ecp_id_tc26_gost_3410_2012_512_paramSetC.c
 179         )
 180
 181 set (GOST_OMAC_SOURCE_FILES
 182         gost_omac.c
 183         gost_omac_acpkm.c
 184         )
 185
 186 set(GOST_LIB_SOURCE_FILES
 187         ${GOST_CORE_SOURCE_FILES}
 188         ${GOST_89_SOURCE_FILES}
 189         ${GOST_HASH_SOURCE_FILES}
 190         ${GOST_HASH_2012_SOURCE_FILES}
 191         ${GOST_GRASSHOPPER_SOURCE_FILES}
 192         ${GOST_EC_SOURCE_FILES}
 193         ${GOST_OMAC_SOURCE_FILES}
 194         )
 195
 196 set(GOST_ENGINE_SOURCE_FILES
 197         gost_eng.c
 198         )
 199
 200 set(GOST_PROV_SOURCE_FILES
 201         gost_prov.c
 202         )
 203
 204 set(TEST_ENVIRONMENT
 205         CMAKE_CURRENT_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}
 206         PERL5LIB=${CMAKE_CURRENT_SOURCE_DIR}/test
 207         OPENSSL_ENGINES=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 208         OPENSSL_PROGRAM=${OPENSSL_PROGRAM}
 209         OPENSSL_CRYPTO_LIBRARY=${OPENSSL_CRYPTO_LIBRARY}
 210         OPENSSL_CONF=${CMAKE_CURRENT_SOURCE_DIR}/test/engine.cnf
 211         )
 212
 213 add_executable(test_digest test_digest.c)
 214 target_link_libraries(test_digest OpenSSL::Crypto)
 215 add_test(NAME digest COMMAND test_digest)
 216 set_tests_properties(digest PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT}")
 217
 218 add_executable(test_ciphers test_ciphers.c)
 219 target_link_libraries(test_ciphers OpenSSL::Crypto)
 220 add_test(NAME ciphers COMMAND test_ciphers)
 221 set_tests_properties(ciphers PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT}")
 222
 223 # test_curves is an internals testing program, it doesn't need a test env
 224 add_executable(test_curves test_curves.c)
 225 target_link_libraries(test_curves gost_core gost_err)
 226 add_test(NAME curves COMMAND test_curves)
 227
 228 add_executable(test_params test_params.c)
 229 target_link_libraries(test_params OpenSSL::Crypto)
 230 add_test(NAME parameters COMMAND test_params)
 231 set_tests_properties(parameters PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT}")
 232
 233 add_executable(test_derive test_derive.c)
 234 target_link_libraries(test_derive OpenSSL::Crypto)
 235 add_test(NAME derive COMMAND test_derive)
 236 set_tests_properties(derive PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT}")
 237
 238 add_executable(test_sign test_sign.c)
 239 target_link_libraries(test_sign OpenSSL::Crypto)
 240 add_test(NAME sign/verify COMMAND test_sign)
 241 set_tests_properties(sign/verify PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT}")
 242
 243 add_executable(test_tls test_tls.c)
 244 target_link_libraries(test_tls OpenSSL::SSL)
 245 add_test(NAME TLS COMMAND test_tls)
 246 set_tests_properties(TLS PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT}")
 247
 248 add_executable(test_context test_context.c)
 249 target_link_libraries(test_context OpenSSL::Crypto)
 250 add_test(NAME context COMMAND test_context)
 251 set_tests_properties(context PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT}")
 252
 253 # test_keyexpimp is an internals testing program, it doesn't need a test env
 254 add_executable(test_keyexpimp test_keyexpimp.c)
 255 #target_compile_definitions(test_keyexpimp PUBLIC -DOPENSSL_LOAD_CONF)
 256 target_link_libraries(test_keyexpimp gost_core gost_err)
 257 add_test(NAME keyexpimp COMMAND test_keyexpimp)
 258
 259 # test_gost89 is an internals testing program, it doesn't need a test env
 260 add_executable(test_gost89 test_gost89.c)
 261 target_link_libraries(test_gost89 gost_core gost_err)
 262 add_test(NAME gost89 COMMAND test_gost89)
 263
 264 if(NOT SKIP_PERL_TESTS)
 265     execute_process(COMMAND perl -MTest2::V0 -e ""
 266         ERROR_QUIET RESULT_VARIABLE HAVE_TEST2_V0)
 267     if(NOT HAVE_TEST2_V0)
 268         add_test(NAME engine
 269             COMMAND prove --merge -PWrapOpenSSL ${CMAKE_CURRENT_SOURCE_DIR}/test)
 270         set_tests_properties(engine PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT}")
 271     else()
 272       message(STATUS "No Test2::V0 perl module (engine tests skipped)")
 273     endif()
 274 endif()
 275
 276 add_executable(sign benchmark/sign.c)
 277 target_link_libraries(sign gost_core gost_err ${CLOCK_GETTIME_LIB})
 278
 279 # All that may need to load just built engine will have path to it defined.
 280 set(BINARY_TESTS_TARGETS
 281         test_digest
 282         test_ciphers
 283         test_curves
 284         test_params
 285         test_derive
 286         test_sign
 287         test_context
 288         test_keyexpimp
 289         test_gost89
 290         test_tls
 291         )
 292 set_property(TARGET ${BINARY_TESTS_TARGETS} APPEND PROPERTY COMPILE_DEFINITIONS ENGINE_DIR="${OUTPUT_DIRECTORY}")
 293
 294 add_library(gost_core STATIC ${GOST_LIB_SOURCE_FILES})
 295 set_target_properties(gost_core PROPERTIES POSITION_INDEPENDENT_CODE ON)
 296 target_link_libraries(gost_core PRIVATE OpenSSL::Crypto)
 297 add_library(gost_err STATIC ${GOST_ERR_SOURCE_FILES})
 298 set_target_properties(gost_err PROPERTIES POSITION_INDEPENDENT_CODE ON)
 299 target_link_libraries(gost_err PRIVATE OpenSSL::Crypto)
 300
 301 # The GOST engine in module form
 302 add_library(gost_engine MODULE ${GOST_ENGINE_SOURCE_FILES})
 303 # Set the suffix explicitly to adapt to OpenSSL's idea of what a
 304 # module suffix should be
 305 set_target_properties(gost_engine PROPERTIES
 306   PREFIX "" OUTPUT_NAME "gost" SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX})
 307 target_link_libraries(gost_engine PRIVATE gost_core gost_err)
 308
 309 # The GOST engine in library form
 310 add_library(lib_gost_engine SHARED ${GOST_ENGINE_SOURCE_FILES})
 311 set_target_properties(lib_gost_engine PROPERTIES
 312   COMPILE_DEFINITIONS "BUILDING_ENGINE_AS_LIBRARY"
 313   PUBLIC_HEADER gost-engine.h
 314   OUTPUT_NAME "gost")
 315 target_link_libraries(lib_gost_engine PRIVATE gost_core gost_err)
 316
 317
 318 # The GOST provider uses this
 319 add_subdirectory(libprov)
 320
 321 # The GOST provider in module form
 322 add_library(gost_prov MODULE
 323   ${GOST_PROV_SOURCE_FILES} ${GOST_ENGINE_SOURCE_FILES}
 324   )
 325 set_target_properties(gost_prov PROPERTIES
 326   PREFIX "" OUTPUT_NAME "gostprov" SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX}
 327   COMPILE_DEFINITIONS "BUILDING_GOST_PROVIDER;OPENSSL_NO_DYNAMIC_ENGINE"
 328   )
 329 target_link_libraries(gost_prov PRIVATE gost_core libprov)
 330
 331 # The GOST provider in library form
 332 add_library(lib_gost_prov SHARED
 333   ${GOST_PROV_SOURCE_FILES} ${GOST_ENGINE_SOURCE_FILES}
 334   )
 335 set_target_properties(lib_gost_prov PROPERTIES
 336   OUTPUT_NAME "gostprov"
 337   COMPILE_DEFINITIONS "BUILDING_GOST_PROVIDER;BUILDING_PROVIDER_AS_LIBRARY;OPENSSL_NO_DYNAMIC_ENGINE"
 338   )
 339 target_link_libraries(lib_gost_prov PRIVATE gost_core libprov)
 340
 341 set(GOST_SUM_SOURCE_FILES
 342         gostsum.c
 343         )
 344
 345 add_executable(gostsum ${GOST_SUM_SOURCE_FILES})
 346 target_link_libraries(gostsum gost_core gost_err)
 347
 348 set(GOST_12_SUM_SOURCE_FILES
 349         gost12sum.c
 350         )
 351
 352 add_executable(gost12sum ${GOST_12_SUM_SOURCE_FILES})
 353 target_link_libraries(gost12sum gost_core gost_err)
 354
 355 set_source_files_properties(tags PROPERTIES GENERATED true)
 356 add_custom_target(tags
 357     COMMAND ctags -R . ${OPENSSL_ROOT_DIR}
 358     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 359
 360 add_custom_target(tcl_tests
 361     COMMAND OPENSSL_LIBCRYPTO=${OPENSSL_CRYPTO_LIBRARY}
 362             OPENSSL_APP=${OPENSSL_PROGRAM}
 363             TESTSRC=${CMAKE_SOURCE_DIR}/tcl_tests
 364             TESTDIR=${CMAKE_BINARY_DIR}/tcl_tests
 365             ENGINE_DIR=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 366             sh ./runtest.sh
 367     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/tcl_tests)
 368
 369 add_executable(test_tlstree test_tlstree.c)
 370 target_link_libraries(test_tlstree PUBLIC OpenSSL::Crypto)
 371
 372 # install programs and manuals
 373 install(TARGETS gostsum gost12sum RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 374 install(FILES gostsum.1 gost12sum.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)
 375
 376 # install engine in library and module form
 377 install(TARGETS lib_gost_engine EXPORT GostEngineConfig LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 378 install(TARGETS gost_engine EXPORT GostEngineConfig
 379         LIBRARY  DESTINATION ${OPENSSL_ENGINES_DIR}
 380         RUNTIME  DESTINATION ${OPENSSL_ENGINES_DIR})
 381 if (MSVC)
 382   install(FILES $<TARGET_PDB_FILE:lib_gost_engine>
 383     EXPORT GostEngineConfig DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 384   install(FILES $<TARGET_PDB_FILE:gostsum> $<TARGET_PDB_FILE:gost12sum>
 385     EXPORT GostEngineConfig DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 386   install(FILES $<TARGET_PDB_FILE:gost_engine>
 387     EXPORT GostEngineConfig DESTINATION ${OPENSSL_ENGINES_DIR} OPTIONAL)
 388 endif()
 389 install(EXPORT GostEngineConfig DESTINATION GostEngine/share/cmake/GostEngine)