CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.18 FATAL_ERROR)
   2 project(gost-engine LANGUAGES C)
   3
   4 include(GNUInstallDirs)
   5 include(CheckLibraryExists)
   6 include(CheckFunctionExists)
   7 include(CheckCSourceRuns)
   8
   9 enable_testing()
  10
  11 find_package(OpenSSL 3.0 REQUIRED)
  12
  13 if (NOT DEFINED OPENSSL_ROOT_DIR)
  14   get_filename_component(OPENSSL_ROOT_DIR ${OPENSSL_INCLUDE_DIR} DIRECTORY)
  15   message(STATUS "Setting OpenSSL root: ${OPENSSL_ROOT_DIR}")
  16 endif()
  17 find_program(OPENSSL_PROGRAM openssl
  18   PATHS ${OPENSSL_ROOT_DIR} PATH_SUFFIXES apps bin NO_DEFAULT_PATH)
  19 message(STATUS "Found OpenSSL application: ${OPENSSL_PROGRAM}")
  20 include_directories(${OPENSSL_INCLUDE_DIR})
  21 set(OPENSSL_MODULES_DIR ${CMAKE_INSTALL_LIBDIR}/ossl-modules)
  22
  23 if (CMAKE_C_COMPILER_ID MATCHES "Clang")
  24   set(CMAKE_C_FLAGS_RELEASE -O2)
  25   set(CMAKE_C_FLAGS_DEBUG "-O0 -ggdb")
  26   set(CMAKE_C_FLAGS_RELWITHDEBINFO "-O2 -ggdb")
  27   add_compile_options(-Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -Qunused-arguments -Wno-deprecated-declarations)
  28 elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
  29   set(CMAKE_C_FLAGS_RELEASE -O2)
  30   set(CMAKE_C_FLAGS_DEBUG "-O0 -ggdb")
  31   set(CMAKE_C_FLAGS_RELWITHDEBINFO "-O2 -ggdb")
  32   add_compile_options(-Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -Wno-error=unknown-pragmas -Wno-error=pragmas -Wno-deprecated-declarations)
  33 elseif(CMAKE_C_COMPILER_ID MATCHES "MSVC")
  34   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
  35   add_definitions(-D_CRT_DEPRECATED_NO_WARNINGS)
  36   add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
  37   add_compile_options(/MP /WX /W4 /wd4100 /wd4267 /wd4206 /wd4706 /wd4244 /wd4115 /wd4996)
  38 endif()
  39
  40 if (ASAN)
  41   message(STATUS "address sanitizer enabled")
  42   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=address -g3 -fno-omit-frame-pointer")
  43   set(SKIP_PERL_TESTS 1)
  44 endif()
  45
  46 set(CMAKE_C_STANDARD 90)
  47 CHECK_FUNCTION_EXISTS(clock_gettime HAVE_CLOCK_GETTIME_C)
  48 CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_CLOCK_GETTIME_RT)
  49 if(HAVE_CLOCK_GETTIME_RT AND NOT HAVE_CLOCK_GETTIME_C)
  50   set(CLOCK_GETTIME_LIB rt)
  51 endif()
  52
  53 include (TestBigEndian)
  54 TEST_BIG_ENDIAN(IS_BIG_ENDIAN)
  55 if(IS_BIG_ENDIAN)
  56  message(STATUS "BIG_ENDIAN")
  57 else()
  58  message(STATUS "LITTLE_ENDIAN")
  59  add_definitions(-DL_ENDIAN)
  60 endif()
  61
  62 check_c_source_runs("
  63   #ifdef _MSC_VER
  64   # include <intrin.h>
  65   #else
  66   # include <x86intrin.h>
  67   #endif
  68   int main(void) {
  69     unsigned long long x = -1, y = 1, r;
  70     unsigned char cf;
  71     cf = _addcarry_u64(1, x, y, &r);
  72     return !(cf == 1 && r == 1);
  73   }
  74   " ADDCARRY_U64)
  75 if (ADDCARRY_U64)
  76   add_definitions(-DHAVE_ADDCARRY_U64)
  77 endif()
  78
  79 check_c_source_runs("
  80   int main(void) {
  81     char buf[16] = { 0, 1, 2 };
  82     int *p = (int *)(buf + 1);
  83     int *q = (int *)(buf + 2);
  84     return (*p == *q);
  85   }
  86   " RELAXED_ALIGNMENT)
  87 if (NOT RELAXED_ALIGNMENT)
  88   add_definitions(-DSTRICT_ALIGNMENT)
  89 endif()
  90
  91 if(MSVC)
  92   set(BIN_DIRECTORY bin/$<CONFIG>/)
  93 else()
  94   set(BIN_DIRECTORY bin)
  95 endif()
  96
  97 set(OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${BIN_DIRECTORY})
  98
  99 #set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 100 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 101 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 102
 103 # Remove when https://gitlab.kitware.com/cmake/cmake/issues/18525 is addressed
 104 set(OPENSSL_ENGINES_DIR "" CACHE PATH "OpenSSL Engines Directory")
 105 if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
 106         include(FindPkgConfig)
 107         pkg_get_variable(OPENSSL_ENGINES_DIR libcrypto enginesdir)
 108         if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
 109                 message( FATAL_ERROR "Unable to discover the OpenSSL engines directory. Provide the path using -DOPENSSL_ENGINES_DIR" )
 110         endif()
 111 endif()
 112
 113 set(GOST_89_SOURCE_FILES
 114         gost89.c
 115         gost89.h
 116         )
 117
 118 set(GOST_HASH_SOURCE_FILES
 119         gosthash.c
 120         gosthash.h
 121         )
 122
 123 set(GOST_HASH_2012_SOURCE_FILES
 124         gosthash2012.c
 125         gosthash2012.h
 126         gosthash2012_const.h
 127         gosthash2012_precalc.h
 128         gosthash2012_ref.h
 129         gosthash2012_sse2.h
 130         )
 131
 132 set(GOST_GRASSHOPPER_SOURCE_FILES
 133         gost_grasshopper.h
 134         gost_grasshopper_core.h
 135         gost_grasshopper_core.c
 136         gost_grasshopper_defines.h
 137         gost_grasshopper_defines.c
 138         gost_grasshopper_math.h
 139         gost_grasshopper_galois_precompiled.c
 140         gost_grasshopper_precompiled.c
 141         gost_grasshopper_cipher.h
 142         gost_grasshopper_cipher.c
 143         )
 144
 145 set(GOST_ERR_SOURCE_FILES
 146         e_gost_err.c
 147         e_gost_err.h
 148         )
 149
 150 set(GOST_CORE_SOURCE_FILES
 151         gost_ameth.c
 152         gost_pmeth.c
 153         gost_ctl.c
 154         gost_asn1.c
 155         gost_crypt.c
 156         gost_keywrap.c
 157         gost_keywrap.h
 158         gost_md.c
 159         gost_md2012.c
 160         gost_omac.c
 161         gost_omac_acpkm.c
 162         gost_gost2015.c
 163         gost_lcl.h
 164         gost_params.c
 165         gost_keyexpimp.c
 166         )
 167
 168 set(GOST_EC_SOURCE_FILES
 169         gost_ec_keyx.c
 170         gost_ec_sign.c
 171         ecp_id_GostR3410_2001_CryptoPro_A_ParamSet.c
 172         ecp_id_GostR3410_2001_CryptoPro_B_ParamSet.c
 173         ecp_id_GostR3410_2001_CryptoPro_C_ParamSet.c
 174         ecp_id_GostR3410_2001_TestParamSet.c
 175         ecp_id_tc26_gost_3410_2012_256_paramSetA.c
 176         ecp_id_tc26_gost_3410_2012_512_paramSetA.c
 177         ecp_id_tc26_gost_3410_2012_512_paramSetB.c
 178         ecp_id_tc26_gost_3410_2012_512_paramSetC.c
 179         )
 180
 181 set (GOST_OMAC_SOURCE_FILES
 182         gost_omac.c
 183         gost_omac_acpkm.c
 184         )
 185
 186 set(GOST_LIB_SOURCE_FILES
 187         ${GOST_CORE_SOURCE_FILES}
 188         ${GOST_89_SOURCE_FILES}
 189         ${GOST_HASH_SOURCE_FILES}
 190         ${GOST_HASH_2012_SOURCE_FILES}
 191         ${GOST_GRASSHOPPER_SOURCE_FILES}
 192         ${GOST_EC_SOURCE_FILES}
 193         ${GOST_OMAC_SOURCE_FILES}
 194         )
 195
 196 set(GOST_ENGINE_SOURCE_FILES
 197         gost_eng.c
 198         )
 199
 200 set(GOST_PROV_SOURCE_FILES
 201         gost_prov.c
 202         gost_prov_cipher.c
 203         gost_prov_digest.c
 204         gost_prov_mac.c
 205         )
 206
 207 set(TEST_ENVIRONMENT_COMMON
 208         CMAKE_CURRENT_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}
 209         PERL5LIB=${CMAKE_CURRENT_SOURCE_DIR}/test
 210         OPENSSL_PROGRAM=${OPENSSL_PROGRAM}
 211         OPENSSL_CRYPTO_LIBRARY=${OPENSSL_CRYPTO_LIBRARY}
 212         )
 213
 214 set(TEST_ENVIRONMENT_ENGINE
 215         ${TEST_ENVIRONMENT_COMMON}
 216         OPENSSL_ENGINES=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 217         OPENSSL_CONF=${CMAKE_CURRENT_SOURCE_DIR}/test/engine.cnf
 218         )
 219
 220 set(TEST_ENVIRONMENT_PROVIDER
 221         ${TEST_ENVIRONMENT_COMMON}
 222         OPENSSL_MODULES=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 223         OPENSSL_CONF=${CMAKE_CURRENT_SOURCE_DIR}/test/provider.cnf
 224         )
 225
 226 add_executable(test_digest test_digest.c)
 227 target_link_libraries(test_digest OpenSSL::Crypto)
 228 add_test(NAME digest-with-engine COMMAND test_digest)
 229 set_tests_properties(digest-with-engine
 230   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 231 add_test(NAME digest-with-provider COMMAND test_digest)
 232 set_tests_properties(digest-with-provider
 233   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 234
 235 add_executable(test_ciphers test_ciphers.c)
 236 target_link_libraries(test_ciphers OpenSSL::Crypto)
 237 add_test(NAME ciphers-with-engine COMMAND test_ciphers)
 238 set_tests_properties(ciphers-with-engine
 239   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 240 add_test(NAME ciphers-with-provider COMMAND test_ciphers)
 241 set_tests_properties(ciphers-with-provider
 242   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 243
 244 # test_curves is an internals testing program, it doesn't need a test env
 245 add_executable(test_curves test_curves.c)
 246 target_link_libraries(test_curves gost_core gost_err)
 247 add_test(NAME curves COMMAND test_curves)
 248
 249 add_executable(test_params test_params.c)
 250 target_link_libraries(test_params OpenSSL::Crypto)
 251 add_test(NAME parameters-with-engine COMMAND test_params)
 252 set_tests_properties(parameters-with-engine
 253   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 254
 255 add_executable(test_derive test_derive.c)
 256 target_link_libraries(test_derive OpenSSL::Crypto)
 257 add_test(NAME derive-with-engine COMMAND test_derive)
 258 set_tests_properties(derive-with-engine
 259   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 260
 261 add_executable(test_sign test_sign.c)
 262 target_link_libraries(test_sign OpenSSL::Crypto)
 263 add_test(NAME sign/verify-with-engine COMMAND test_sign)
 264 set_tests_properties(sign/verify-with-engine
 265   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 266
 267 if(NOT MSVC)
 268   add_executable(test_tls test_tls.c)
 269   target_link_libraries(test_tls OpenSSL::SSL)
 270   add_test(NAME TLS-with-engine COMMAND test_tls)
 271   set_tests_properties(TLS-with-engine
 272     PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 273 endif()
 274
 275 add_executable(test_context test_context.c)
 276 target_link_libraries(test_context OpenSSL::Crypto)
 277 add_test(NAME context-with-engine COMMAND test_context)
 278 set_tests_properties(context-with-engine
 279   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 280 add_test(NAME context-with-provider COMMAND test_context)
 281 set_tests_properties(context-with-provider
 282   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 283
 284 # test_keyexpimp is an internals testing program, it doesn't need a test env
 285 add_executable(test_keyexpimp test_keyexpimp.c)
 286 #target_compile_definitions(test_keyexpimp PUBLIC -DOPENSSL_LOAD_CONF)
 287 target_link_libraries(test_keyexpimp gost_core gost_err)
 288 add_test(NAME keyexpimp COMMAND test_keyexpimp)
 289
 290 # test_gost89 is an internals testing program, it doesn't need a test env
 291 add_executable(test_gost89 test_gost89.c)
 292 target_link_libraries(test_gost89 gost_core gost_err)
 293 add_test(NAME gost89 COMMAND test_gost89)
 294
 295 if(NOT SKIP_PERL_TESTS)
 296     execute_process(COMMAND perl -MTest2::V0 -e ""
 297        ERROR_QUIET RESULT_VARIABLE MISSING_TEST2_V0)
 298     find_program(HAVE_PROVE NAMES prove)
 299     if(NOT MISSING_TEST2_V0 AND HAVE_PROVE)
 300         add_test(NAME engine
 301             COMMAND prove --merge -PWrapOpenSSL ${CMAKE_CURRENT_SOURCE_DIR}/test :: engine)
 302         set_tests_properties(engine PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 303         add_test(NAME provider
 304             COMMAND prove --merge -PWrapOpenSSL ${CMAKE_CURRENT_SOURCE_DIR}/test :: provider)
 305         set_tests_properties(provider PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 306     else()
 307         message(STATUS "No Test2::V0 perl module (engine and provider tests skipped)")
 308     endif()
 309 endif()
 310
 311 if(NOT MSVC)
 312   add_executable(sign benchmark/sign.c)
 313   target_link_libraries(sign gost_core gost_err ${CLOCK_GETTIME_LIB})
 314 endif()
 315
 316 # All that may need to load just built engine will have path to it defined.
 317 set(BINARY_TESTS_TARGETS
 318         test_digest
 319         test_ciphers
 320         test_curves
 321         test_params
 322         test_derive
 323         test_sign
 324         test_context
 325         test_keyexpimp
 326         test_gost89
 327         )
 328 if(NOT MSVC)
 329   list(APPEND BINARY_TESTS_TARGETS test_tls)
 330 endif()
 331 set_property(TARGET ${BINARY_TESTS_TARGETS} APPEND PROPERTY COMPILE_DEFINITIONS ENGINE_DIR="${OUTPUT_DIRECTORY}")
 332
 333 add_library(gost_core STATIC ${GOST_LIB_SOURCE_FILES})
 334 set_target_properties(gost_core PROPERTIES POSITION_INDEPENDENT_CODE ON)
 335 target_link_libraries(gost_core PRIVATE OpenSSL::Crypto)
 336 add_library(gost_err STATIC ${GOST_ERR_SOURCE_FILES})
 337 set_target_properties(gost_err PROPERTIES POSITION_INDEPENDENT_CODE ON)
 338 target_link_libraries(gost_err PRIVATE OpenSSL::Crypto)
 339
 340 # The GOST engine in module form
 341 add_library(gost_engine MODULE ${GOST_ENGINE_SOURCE_FILES})
 342 # Set the suffix explicitly to adapt to OpenSSL's idea of what a
 343 # module suffix should be
 344 set_target_properties(gost_engine PROPERTIES
 345   PREFIX "" OUTPUT_NAME "gost" SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX})
 346 target_link_libraries(gost_engine PRIVATE gost_core gost_err)
 347
 348 if (NOT MSVC)
 349 # The GOST engine in library form
 350 add_library(lib_gost_engine SHARED ${GOST_ENGINE_SOURCE_FILES})
 351 set_target_properties(lib_gost_engine PROPERTIES
 352   COMPILE_DEFINITIONS "BUILDING_ENGINE_AS_LIBRARY"
 353   PUBLIC_HEADER gost-engine.h
 354   OUTPUT_NAME "gost")
 355 target_link_libraries(lib_gost_engine PRIVATE gost_core gost_err)
 356 endif()
 357
 358 # The GOST provider uses this
 359 add_subdirectory(libprov)
 360
 361 # The GOST provider in module form
 362 add_library(gost_prov MODULE
 363   ${GOST_PROV_SOURCE_FILES} ${GOST_ENGINE_SOURCE_FILES}
 364   )
 365 set_target_properties(gost_prov PROPERTIES
 366   PREFIX "" OUTPUT_NAME "gostprov" SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX}
 367   COMPILE_DEFINITIONS "BUILDING_GOST_PROVIDER;OPENSSL_NO_DYNAMIC_ENGINE"
 368   )
 369 target_link_libraries(gost_prov PRIVATE gost_core libprov)
 370
 371 if (NOT MSVC)
 372 # The GOST provider in library form
 373 add_library(lib_gost_prov SHARED
 374   ${GOST_PROV_SOURCE_FILES} ${GOST_ENGINE_SOURCE_FILES}
 375   )
 376 set_target_properties(lib_gost_prov PROPERTIES
 377   OUTPUT_NAME "gostprov"
 378   COMPILE_DEFINITIONS "BUILDING_GOST_PROVIDER;BUILDING_PROVIDER_AS_LIBRARY;OPENSSL_NO_DYNAMIC_ENGINE"
 379   )
 380 target_link_libraries(lib_gost_prov PRIVATE gost_core libprov)
 381 endif()
 382
 383 set(GOST_SUM_SOURCE_FILES
 384         gostsum.c
 385         )
 386
 387 add_executable(gostsum ${GOST_SUM_SOURCE_FILES})
 388 target_link_libraries(gostsum gost_core gost_err)
 389
 390 set(GOST_12_SUM_SOURCE_FILES
 391         gost12sum.c
 392         )
 393
 394 add_executable(gost12sum ${GOST_12_SUM_SOURCE_FILES})
 395 target_link_libraries(gost12sum gost_core gost_err)
 396
 397 set_source_files_properties(tags PROPERTIES GENERATED true)
 398 add_custom_target(tags
 399     COMMAND ctags -R . ${OPENSSL_ROOT_DIR}
 400     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 401
 402 add_custom_target(tcl_tests
 403     COMMAND OPENSSL_LIBCRYPTO=${OPENSSL_CRYPTO_LIBRARY}
 404             OPENSSL_APP=${OPENSSL_PROGRAM}
 405             TESTSRC=${CMAKE_SOURCE_DIR}/tcl_tests
 406             TESTDIR=${CMAKE_BINARY_DIR}/tcl_tests
 407             ENGINE_DIR=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 408             sh ./runtest.sh
 409     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/tcl_tests)
 410
 411 add_executable(test_tlstree test_tlstree.c)
 412 target_link_libraries(test_tlstree PUBLIC OpenSSL::Crypto)
 413
 414 # install programs and manuals
 415 install(TARGETS gostsum gost12sum RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 416 install(FILES gostsum.1 gost12sum.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)
 417
 418 # install engine and provider in module form
 419 install(TARGETS gost_engine EXPORT GostEngineConfig
 420         LIBRARY  DESTINATION ${OPENSSL_ENGINES_DIR}
 421         RUNTIME  DESTINATION ${OPENSSL_ENGINES_DIR})
 422 install(TARGETS gost_prov EXPORT GostProviderConfig
 423         LIBRARY  DESTINATION ${OPENSSL_MODULES_DIR}
 424         RUNTIME  DESTINATION ${OPENSSL_MODULES_DIR})
 425 if (NOT MSVC)
 426 # install engine and provider in library form
 427 install(TARGETS lib_gost_engine EXPORT GostEngineConfig
 428         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 429 install(TARGETS lib_gost_prov EXPORT GostProviderConfig
 430         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 431 endif()
 432
 433 if (MSVC)
 434   install(FILES $<TARGET_PDB_FILE:gostsum> $<TARGET_PDB_FILE:gost12sum>
 435     EXPORT GostEngineConfig DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 436   install(FILES $<TARGET_PDB_FILE:gost_engine>
 437     EXPORT GostEngineConfig DESTINATION ${OPENSSL_ENGINES_DIR} OPTIONAL)
 438   install(FILES $<TARGET_PDB_FILE:gost_prov>
 439     EXPORT GostProviderConfig DESTINATION ${OPENSSL_MODULES_DIR} OPTIONAL)
 440 endif()
 441 install(EXPORT GostEngineConfig DESTINATION GostEngine/share/cmake/GostEngine)
 442 install(EXPORT GostProviderConfig DESTINATION GostEngine/share/cmake/GostProvider)