CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.18 FATAL_ERROR)
   2 project(gost-engine LANGUAGES C)
   3
   4 include(GNUInstallDirs)
   5 include(CheckLibraryExists)
   6 include(CheckFunctionExists)
   7 include(CheckCSourceRuns)
   8
   9 enable_testing()
  10
  11 find_package(OpenSSL 3.0 REQUIRED)
  12
  13 if (NOT DEFINED OPENSSL_ROOT_DIR)
  14   get_filename_component(OPENSSL_ROOT_DIR ${OPENSSL_INCLUDE_DIR} DIRECTORY)
  15   message(STATUS "Setting OpenSSL root: ${OPENSSL_ROOT_DIR}")
  16 endif()
  17 find_program(OPENSSL_PROGRAM openssl
  18   PATHS ${OPENSSL_ROOT_DIR} PATH_SUFFIXES apps bin NO_DEFAULT_PATH)
  19 message(STATUS "Found OpenSSL application: ${OPENSSL_PROGRAM}")
  20 include_directories(${OPENSSL_INCLUDE_DIR})
  21
  22 if (CMAKE_C_COMPILER_ID MATCHES "Clang")
  23   set(CMAKE_C_FLAGS_RELEASE -O2)
  24   set(CMAKE_C_FLAGS_DEBUG "-O0 -ggdb")
  25   set(CMAKE_C_FLAGS_RELWITHDEBINFO "-O2 -ggdb")
  26   add_compile_options(-Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -Qunused-arguments -Wno-deprecated-declarations)
  27 elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
  28   set(CMAKE_C_FLAGS_RELEASE -O2)
  29   set(CMAKE_C_FLAGS_DEBUG "-O0 -ggdb")
  30   set(CMAKE_C_FLAGS_RELWITHDEBINFO "-O2 -ggdb")
  31   add_compile_options(-Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -Wno-error=unknown-pragmas -Wno-error=pragmas -Wno-deprecated-declarations)
  32 elseif(CMAKE_C_COMPILER_ID MATCHES "MSVC")
  33   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
  34   add_definitions(-D_CRT_DEPRECATED_NO_WARNINGS)
  35   add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
  36   add_compile_options(/MP /WX /W4 /wd4100 /wd4267 /wd4206 /wd4706 /wd4244 /wd4115)
  37 endif()
  38
  39 if (ASAN)
  40   message(STATUS "address sanitizer enabled")
  41   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=address -g3 -fno-omit-frame-pointer")
  42   set(SKIP_PERL_TESTS 1)
  43 endif()
  44
  45 # DEPRECATEDIN_3_0 CMAC
  46 set_source_files_properties(gost_omac.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  47 # DEPRECATEDIN_3_0 HMAC
  48 set_source_files_properties(gost_keyexpimp.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  49
  50 set(CMAKE_C_STANDARD 90)
  51 CHECK_FUNCTION_EXISTS(clock_gettime HAVE_CLOCK_GETTIME_C)
  52 CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_CLOCK_GETTIME_RT)
  53 if(HAVE_CLOCK_GETTIME_RT AND NOT HAVE_CLOCK_GETTIME_C)
  54   set(CLOCK_GETTIME_LIB rt)
  55 endif()
  56
  57 include (TestBigEndian)
  58 TEST_BIG_ENDIAN(IS_BIG_ENDIAN)
  59 if(IS_BIG_ENDIAN)
  60  message(STATUS "BIG_ENDIAN")
  61 else()
  62  message(STATUS "LITTLE_ENDIAN")
  63  add_definitions(-DL_ENDIAN)
  64 endif()
  65
  66 check_c_source_runs("
  67   #ifdef _MSC_VER
  68   # include <intrin.h>
  69   #else
  70   # include <x86intrin.h>
  71   #endif
  72   int main(void) {
  73     unsigned long long x = -1, y = 1, r;
  74     unsigned char cf;
  75     cf = _addcarry_u64(1, x, y, &r);
  76     return !(cf == 1 && r == 1);
  77   }
  78   " ADDCARRY_U64)
  79 if (ADDCARRY_U64)
  80   add_definitions(-DHAVE_ADDCARRY_U64)
  81 endif()
  82
  83 check_c_source_runs("
  84   int main(void) {
  85     char buf[16] = { 0, 1, 2 };
  86     int *p = (int *)(buf + 1);
  87     int *q = (int *)(buf + 2);
  88     return (*p == *q);
  89   }
  90   " RELAXED_ALIGNMENT)
  91 if (NOT RELAXED_ALIGNMENT)
  92   add_definitions(-DSTRICT_ALIGNMENT)
  93 endif()
  94
  95 set(BIN_DIRECTORY bin)
  96
  97 set(OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${BIN_DIRECTORY})
  98
  99 #set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 100 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 101 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
 102
 103 # Remove when https://gitlab.kitware.com/cmake/cmake/issues/18525 is addressed
 104 set(OPENSSL_ENGINES_DIR "" CACHE PATH "OpenSSL Engines Directory")
 105 if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
 106         include(FindPkgConfig)
 107         pkg_get_variable(OPENSSL_ENGINES_DIR libcrypto enginesdir)
 108         if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
 109                 message( FATAL_ERROR "Unable to discover the OpenSSL engines directory. Provide the path using -DOPENSSL_ENGINES_DIR" )
 110         endif()
 111 endif()
 112
 113 set(GOST_89_SOURCE_FILES
 114         gost89.c
 115         gost89.h
 116         )
 117
 118 set(GOST_HASH_SOURCE_FILES
 119         gosthash.c
 120         gosthash.h
 121         )
 122
 123 set(GOST_HASH_2012_SOURCE_FILES
 124         gosthash2012.c
 125         gosthash2012.h
 126         gosthash2012_const.h
 127         gosthash2012_precalc.h
 128         gosthash2012_ref.h
 129         gosthash2012_sse2.h
 130         )
 131
 132 set(GOST_GRASSHOPPER_SOURCE_FILES
 133         gost_grasshopper.h
 134         gost_grasshopper_core.h
 135         gost_grasshopper_core.c
 136         gost_grasshopper_defines.h
 137         gost_grasshopper_defines.c
 138         gost_grasshopper_math.h
 139         gost_grasshopper_galois_precompiled.c
 140         gost_grasshopper_precompiled.c
 141         gost_grasshopper_cipher.h
 142         gost_grasshopper_cipher.c
 143         )
 144
 145 set(GOST_ERR_SOURCE_FILES
 146         e_gost_err.c
 147         e_gost_err.h
 148         )
 149
 150 set(GOST_CORE_SOURCE_FILES
 151         gost_ameth.c
 152         gost_pmeth.c
 153         gost_ctl.c
 154         gost_asn1.c
 155         gost_crypt.c
 156         gost_keywrap.c
 157         gost_keywrap.h
 158         gost_md.c
 159         gost_md2012.c
 160         gost_omac.c
 161         gost_omac_acpkm.c
 162         gost_gost2015.c
 163         gost_lcl.h
 164         gost_params.c
 165         gost_keyexpimp.c
 166         )
 167
 168 set(GOST_EC_SOURCE_FILES
 169         gost_ec_keyx.c
 170         gost_ec_sign.c
 171         ecp_id_GostR3410_2001_CryptoPro_A_ParamSet.c
 172         ecp_id_GostR3410_2001_CryptoPro_B_ParamSet.c
 173         ecp_id_GostR3410_2001_CryptoPro_C_ParamSet.c
 174         ecp_id_GostR3410_2001_TestParamSet.c
 175         ecp_id_tc26_gost_3410_2012_256_paramSetA.c
 176         ecp_id_tc26_gost_3410_2012_512_paramSetA.c
 177         ecp_id_tc26_gost_3410_2012_512_paramSetB.c
 178         ecp_id_tc26_gost_3410_2012_512_paramSetC.c
 179         )
 180
 181 set (GOST_OMAC_SOURCE_FILES
 182         gost_omac.c
 183         gost_omac_acpkm.c
 184         )
 185
 186 set(GOST_LIB_SOURCE_FILES
 187         ${GOST_CORE_SOURCE_FILES}
 188         ${GOST_89_SOURCE_FILES}
 189         ${GOST_HASH_SOURCE_FILES}
 190         ${GOST_HASH_2012_SOURCE_FILES}
 191         ${GOST_GRASSHOPPER_SOURCE_FILES}
 192         ${GOST_EC_SOURCE_FILES}
 193         ${GOST_OMAC_SOURCE_FILES}
 194         )
 195
 196 set(GOST_ENGINE_SOURCE_FILES
 197         gost_eng.c
 198         )
 199
 200 set(GOST_PROV_SOURCE_FILES
 201         gost_prov.c
 202         )
 203
 204 set(TEST_ENVIRONMENT_COMMON
 205         CMAKE_CURRENT_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}
 206         PERL5LIB=${CMAKE_CURRENT_SOURCE_DIR}/test
 207         OPENSSL_PROGRAM=${OPENSSL_PROGRAM}
 208         OPENSSL_CRYPTO_LIBRARY=${OPENSSL_CRYPTO_LIBRARY}
 209         )
 210
 211 set(TEST_ENVIRONMENT_ENGINE
 212         ${TEST_ENVIRONMENT_COMMON}
 213         OPENSSL_ENGINES=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 214         OPENSSL_CONF=${CMAKE_CURRENT_SOURCE_DIR}/test/engine.cnf
 215         )
 216
 217 set(TEST_ENVIRONMENT_PROVIDER
 218         ${TEST_ENVIRONMENT_COMMON}
 219         OPENSSL_MODULES=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 220         OPENSSL_CONF=${CMAKE_CURRENT_SOURCE_DIR}/test/provider.cnf
 221         )
 222
 223 add_executable(test_digest test_digest.c)
 224 target_link_libraries(test_digest OpenSSL::Crypto)
 225 add_test(NAME digest-with-engine COMMAND test_digest)
 226 set_tests_properties(digest-with-engine
 227   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 228
 229 add_executable(test_ciphers test_ciphers.c)
 230 target_link_libraries(test_ciphers OpenSSL::Crypto)
 231 add_test(NAME ciphers-with-engine COMMAND test_ciphers)
 232 set_tests_properties(ciphers-with-engine
 233   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 234
 235 # test_curves is an internals testing program, it doesn't need a test env
 236 add_executable(test_curves test_curves.c)
 237 target_link_libraries(test_curves gost_core gost_err)
 238 add_test(NAME curves COMMAND test_curves)
 239
 240 add_executable(test_params test_params.c)
 241 target_link_libraries(test_params OpenSSL::Crypto)
 242 add_test(NAME parameters-with-engine COMMAND test_params)
 243 set_tests_properties(parameters-with-engine
 244   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 245
 246 add_executable(test_derive test_derive.c)
 247 target_link_libraries(test_derive OpenSSL::Crypto)
 248 add_test(NAME derive-with-engine COMMAND test_derive)
 249 set_tests_properties(derive-with-engine
 250   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 251
 252 add_executable(test_sign test_sign.c)
 253 target_link_libraries(test_sign OpenSSL::Crypto)
 254 add_test(NAME sign/verify-with-engine COMMAND test_sign)
 255 set_tests_properties(sign/verify-with-engine
 256   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 257
 258 add_executable(test_tls test_tls.c)
 259 target_link_libraries(test_tls OpenSSL::SSL)
 260 add_test(NAME TLS-with-engine COMMAND test_tls)
 261 set_tests_properties(TLS-with-engine
 262   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 263
 264 add_executable(test_context test_context.c)
 265 target_link_libraries(test_context OpenSSL::Crypto)
 266 add_test(NAME context-with-engine COMMAND test_context)
 267 set_tests_properties(context-with-engine
 268   PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 269
 270 # test_keyexpimp is an internals testing program, it doesn't need a test env
 271 add_executable(test_keyexpimp test_keyexpimp.c)
 272 #target_compile_definitions(test_keyexpimp PUBLIC -DOPENSSL_LOAD_CONF)
 273 target_link_libraries(test_keyexpimp gost_core gost_err)
 274 add_test(NAME keyexpimp COMMAND test_keyexpimp)
 275
 276 # test_gost89 is an internals testing program, it doesn't need a test env
 277 add_executable(test_gost89 test_gost89.c)
 278 target_link_libraries(test_gost89 gost_core gost_err)
 279 add_test(NAME gost89 COMMAND test_gost89)
 280
 281 if(NOT SKIP_PERL_TESTS)
 282     execute_process(COMMAND perl -MTest2::V0 -e ""
 283         ERROR_QUIET RESULT_VARIABLE HAVE_TEST2_V0)
 284     if(NOT HAVE_TEST2_V0)
 285         add_test(NAME engine
 286             COMMAND prove --merge -PWrapOpenSSL ${CMAKE_CURRENT_SOURCE_DIR}/test :: engine)
 287         set_tests_properties(engine PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_ENGINE}")
 288         add_test(NAME provider
 289             COMMAND prove --merge -PWrapOpenSSL ${CMAKE_CURRENT_SOURCE_DIR}/test :: provider)
 290         set_tests_properties(provider PROPERTIES ENVIRONMENT "${TEST_ENVIRONMENT_PROVIDER}")
 291     else()
 292         message(STATUS "No Test2::V0 perl module (engine and provider tests skipped)")
 293     endif()
 294 endif()
 295
 296 add_executable(sign benchmark/sign.c)
 297 target_link_libraries(sign gost_core gost_err ${CLOCK_GETTIME_LIB})
 298
 299 # All that may need to load just built engine will have path to it defined.
 300 set(BINARY_TESTS_TARGETS
 301         test_digest
 302         test_ciphers
 303         test_curves
 304         test_params
 305         test_derive
 306         test_sign
 307         test_context
 308         test_keyexpimp
 309         test_gost89
 310         test_tls
 311         )
 312 set_property(TARGET ${BINARY_TESTS_TARGETS} APPEND PROPERTY COMPILE_DEFINITIONS ENGINE_DIR="${OUTPUT_DIRECTORY}")
 313
 314 add_library(gost_core STATIC ${GOST_LIB_SOURCE_FILES})
 315 set_target_properties(gost_core PROPERTIES POSITION_INDEPENDENT_CODE ON)
 316 target_link_libraries(gost_core PRIVATE OpenSSL::Crypto)
 317 add_library(gost_err STATIC ${GOST_ERR_SOURCE_FILES})
 318 set_target_properties(gost_err PROPERTIES POSITION_INDEPENDENT_CODE ON)
 319 target_link_libraries(gost_err PRIVATE OpenSSL::Crypto)
 320
 321 # The GOST engine in module form
 322 add_library(gost_engine MODULE ${GOST_ENGINE_SOURCE_FILES})
 323 # Set the suffix explicitly to adapt to OpenSSL's idea of what a
 324 # module suffix should be
 325 set_target_properties(gost_engine PROPERTIES
 326   PREFIX "" OUTPUT_NAME "gost" SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX})
 327 target_link_libraries(gost_engine PRIVATE gost_core gost_err)
 328
 329 # The GOST engine in library form
 330 add_library(lib_gost_engine SHARED ${GOST_ENGINE_SOURCE_FILES})
 331 set_target_properties(lib_gost_engine PROPERTIES
 332   COMPILE_DEFINITIONS "BUILDING_ENGINE_AS_LIBRARY"
 333   PUBLIC_HEADER gost-engine.h
 334   OUTPUT_NAME "gost")
 335 target_link_libraries(lib_gost_engine PRIVATE gost_core gost_err)
 336
 337
 338 # The GOST provider uses this
 339 add_subdirectory(libprov)
 340
 341 # The GOST provider in module form
 342 add_library(gost_prov MODULE
 343   ${GOST_PROV_SOURCE_FILES} ${GOST_ENGINE_SOURCE_FILES}
 344   )
 345 set_target_properties(gost_prov PROPERTIES
 346   PREFIX "" OUTPUT_NAME "gostprov" SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX}
 347   COMPILE_DEFINITIONS "BUILDING_GOST_PROVIDER;OPENSSL_NO_DYNAMIC_ENGINE"
 348   )
 349 target_link_libraries(gost_prov PRIVATE gost_core libprov)
 350
 351 # The GOST provider in library form
 352 add_library(lib_gost_prov SHARED
 353   ${GOST_PROV_SOURCE_FILES} ${GOST_ENGINE_SOURCE_FILES}
 354   )
 355 set_target_properties(lib_gost_prov PROPERTIES
 356   OUTPUT_NAME "gostprov"
 357   COMPILE_DEFINITIONS "BUILDING_GOST_PROVIDER;BUILDING_PROVIDER_AS_LIBRARY;OPENSSL_NO_DYNAMIC_ENGINE"
 358   )
 359 target_link_libraries(lib_gost_prov PRIVATE gost_core libprov)
 360
 361 set(GOST_SUM_SOURCE_FILES
 362         gostsum.c
 363         )
 364
 365 add_executable(gostsum ${GOST_SUM_SOURCE_FILES})
 366 target_link_libraries(gostsum gost_core gost_err)
 367
 368 set(GOST_12_SUM_SOURCE_FILES
 369         gost12sum.c
 370         )
 371
 372 add_executable(gost12sum ${GOST_12_SUM_SOURCE_FILES})
 373 target_link_libraries(gost12sum gost_core gost_err)
 374
 375 set_source_files_properties(tags PROPERTIES GENERATED true)
 376 add_custom_target(tags
 377     COMMAND ctags -R . ${OPENSSL_ROOT_DIR}
 378     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 379
 380 add_custom_target(tcl_tests
 381     COMMAND OPENSSL_LIBCRYPTO=${OPENSSL_CRYPTO_LIBRARY}
 382             OPENSSL_APP=${OPENSSL_PROGRAM}
 383             TESTSRC=${CMAKE_SOURCE_DIR}/tcl_tests
 384             TESTDIR=${CMAKE_BINARY_DIR}/tcl_tests
 385             ENGINE_DIR=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
 386             sh ./runtest.sh
 387     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/tcl_tests)
 388
 389 add_executable(test_tlstree test_tlstree.c)
 390 target_link_libraries(test_tlstree PUBLIC OpenSSL::Crypto)
 391
 392 # install programs and manuals
 393 install(TARGETS gostsum gost12sum RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 394 install(FILES gostsum.1 gost12sum.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)
 395
 396 # install engine in library and module form
 397 install(TARGETS lib_gost_engine EXPORT GostEngineConfig LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 398 install(TARGETS gost_engine EXPORT GostEngineConfig
 399         LIBRARY  DESTINATION ${OPENSSL_ENGINES_DIR}
 400         RUNTIME  DESTINATION ${OPENSSL_ENGINES_DIR})
 401 if (MSVC)
 402   install(FILES $<TARGET_PDB_FILE:lib_gost_engine>
 403     EXPORT GostEngineConfig DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 404   install(FILES $<TARGET_PDB_FILE:gostsum> $<TARGET_PDB_FILE:gost12sum>
 405     EXPORT GostEngineConfig DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 406   install(FILES $<TARGET_PDB_FILE:gost_engine>
 407     EXPORT GostEngineConfig DESTINATION ${OPENSSL_ENGINES_DIR} OPTIONAL)
 408 endif()
 409 install(EXPORT GostEngineConfig DESTINATION GostEngine/share/cmake/GostEngine)