CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.18 FATAL_ERROR)
   2 project(gost-engine LANGUAGES C)
   3
   4 include(GNUInstallDirs)
   5 include(CheckLibraryExists)
   6 include(CheckFunctionExists)
   7 include(CheckCSourceRuns)
   8
   9 enable_testing()
  10
  11 find_package(OpenSSL 1.1.1 REQUIRED)
  12 include_directories(${OPENSSL_INCLUDE_DIR})
  13
  14 if (CMAKE_C_COMPILER_ID MATCHES "Clang")
  15  add_compile_options(-O2 -Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -ggdb -Qunused-arguments)
  16 elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
  17  add_compile_options(-O2 -Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -ggdb -Wno-error=unknown-pragmas)
  18 elseif(CMAKE_C_COMPILER_ID MATCHES "MSVC")
  19  add_definitions(-D_CRT_SECURE_NO_WARNINGS)
  20  add_definitions(-D_CRT_DEPRECATED_NO_WARNINGS)
  21  add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
  22  add_compile_options(/MP /WX /W4 /wd4100 /wd4267 /wd4206 /wd4706 /wd4244 /wd4115)
  23 endif()
  24
  25 if (ASAN)
  26   message(STATUS "address sanitizer enabled")
  27   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=address -g3 -fno-omit-frame-pointer")
  28   set(SKIP_PERL_TESTS 1)
  29 endif()
  30
  31 # DEPRECATEDIN_3_0 CMAC
  32 set_source_files_properties(gost_omac.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  33 # DEPRECATEDIN_3_0 HMAC
  34 set_source_files_properties(gost_keyexpimp.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  35
  36 set(CMAKE_C_STANDARD 90)
  37 CHECK_FUNCTION_EXISTS(clock_gettime HAVE_CLOCK_GETTIME_C)
  38 CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_CLOCK_GETTIME_RT)
  39 if(HAVE_CLOCK_GETTIME_RT AND NOT HAVE_CLOCK_GETTIME_C)
  40   set(CLOCK_GETTIME_LIB rt)
  41 endif()
  42
  43 include (TestBigEndian)
  44 TEST_BIG_ENDIAN(IS_BIG_ENDIAN)
  45 if(IS_BIG_ENDIAN)
  46  message(STATUS "BIG_ENDIAN")
  47 else()
  48  message(STATUS "LITTLE_ENDIAN")
  49  add_definitions(-DL_ENDIAN)
  50 endif()
  51
  52 if (NOT CMAKE_CROSSCOMPILING)
  53   check_c_source_runs("
  54     #ifdef _MSC_VER
  55     # include <intrin.h>
  56     #else
  57     # include <x86intrin.h>
  58     #endif
  59     int main(void) {
  60       unsigned long long x = -1, y = 1, r;
  61       unsigned char cf;
  62       cf = _addcarry_u64(1, x, y, &r);
  63       return !(cf == 1 && r == 1);
  64     }
  65     " ADDCARRY_U64)
  66   if (ADDCARRY_U64)
  67     add_definitions(-DHAVE_ADDCARRY_U64)
  68   endif()
  69 endif(NOT CMAKE_CROSSCOMPILING)
  70
  71 if (NOT CMAKE_CROSSCOMPILING)
  72   check_c_source_runs("
  73     int main(void) {
  74       char buf[16] = { 0, 1, 2 };
  75       int *p = (int *)(buf + 1);
  76       int *q = (int *)(buf + 2);
  77       return (*p == *q);
  78     }
  79     " RELAXED_ALIGNMENT)
  80   if (NOT RELAXED_ALIGNMENT)
  81     add_definitions(-DSTRICT_ALIGNMENT)
  82   endif()
  83 endif(NOT CMAKE_CROSSCOMPILING)
  84
  85 set(BIN_DIRECTORY bin)
  86
  87 # Same soversion as OpenSSL
  88 set(GOST_SOVERSION "${OPENSSL_VERSION_MAJOR}.${OPENSSL_VERSION_MINOR}")
  89
  90 set(OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${BIN_DIRECTORY})
  91
  92 #set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  93 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  94 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  95
  96 # Remove when https://gitlab.kitware.com/cmake/cmake/issues/18525 is addressed
  97 set(OPENSSL_ENGINES_DIR "" CACHE PATH "OpenSSL Engines Directory")
  98 if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
  99         include(FindPkgConfig)
 100         pkg_get_variable(OPENSSL_ENGINES_DIR libcrypto enginesdir)
 101         if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
 102                 message( FATAL_ERROR "Unable to discover the OpenSSL engines directory. Provide the path using -DOPENSSL_ENGINES_DIR" )
 103         endif()
 104 endif()
 105
 106 set(GOST_89_SOURCE_FILES
 107         gost89.c
 108         gost89.h
 109         )
 110
 111 set(GOST_HASH_SOURCE_FILES
 112         gosthash.c
 113         gosthash.h
 114         )
 115
 116 set(GOST_HASH_2012_SOURCE_FILES
 117         gosthash2012.c
 118         gosthash2012.h
 119         gosthash2012_const.h
 120         gosthash2012_precalc.h
 121         gosthash2012_ref.h
 122         gosthash2012_sse2.h
 123         )
 124
 125 set(GOST_GRASSHOPPER_SOURCE_FILES
 126         gost_grasshopper.h
 127         gost_grasshopper_core.h
 128         gost_grasshopper_core.c
 129         gost_grasshopper_defines.h
 130         gost_grasshopper_defines.c
 131         gost_grasshopper_math.h
 132         gost_grasshopper_galois_precompiled.c
 133         gost_grasshopper_precompiled.c
 134         gost_grasshopper_cipher.h
 135         gost_grasshopper_cipher.c
 136         )
 137
 138 set(GOST_CORE_SOURCE_FILES
 139         e_gost_err.c
 140         e_gost_err.h
 141         gost_asn1.c
 142         gost_crypt.c
 143         gost_ctl.c
 144         gost_eng.c
 145         gost_lcl.h
 146         gost_params.c
 147         )
 148
 149 set(GOST_EC_SOURCE_FILES
 150         gost_ec_keyx.c
 151         gost_ec_sign.c
 152         ecp_id_GostR3410_2001_CryptoPro_A_ParamSet.c
 153         ecp_id_GostR3410_2001_CryptoPro_B_ParamSet.c
 154         ecp_id_GostR3410_2001_CryptoPro_C_ParamSet.c
 155         ecp_id_GostR3410_2001_TestParamSet.c
 156         ecp_id_tc26_gost_3410_2012_256_paramSetA.c
 157         ecp_id_tc26_gost_3410_2012_512_paramSetA.c
 158         ecp_id_tc26_gost_3410_2012_512_paramSetB.c
 159         ecp_id_tc26_gost_3410_2012_512_paramSetC.c
 160         )
 161
 162 set (GOST_OMAC_SOURCE_FILES
 163         gost_omac.c
 164         gost_omac_acpkm.c
 165         )
 166
 167 set(GOST_LIB_SOURCE_FILES
 168         ${GOST_89_SOURCE_FILES}
 169         ${GOST_HASH_SOURCE_FILES}
 170         ${GOST_HASH_2012_SOURCE_FILES}
 171         ${GOST_GRASSHOPPER_SOURCE_FILES}
 172         ${GOST_EC_SOURCE_FILES}
 173         ${GOST_OMAC_SOURCE_FILES}
 174         gost_keyexpimp.c
 175         gost_keywrap.c
 176         gost_keywrap.h
 177         )
 178
 179 set(GOST_ENGINE_SOURCE_FILES
 180         ${GOST_CORE_SOURCE_FILES}
 181         gost_ameth.c
 182         gost_md.c
 183         gost_md2012.c
 184         gost_pmeth.c
 185         )
 186
 187 add_executable(test_digest test_digest.c)
 188 target_link_libraries(test_digest OpenSSL::Crypto)
 189 add_test(NAME digest
 190         COMMAND test_digest)
 191
 192 add_executable(test_curves test_curves.c)
 193 target_link_libraries(test_curves gost_engine OpenSSL::Crypto)
 194 add_test(NAME curves
 195         COMMAND test_curves)
 196
 197 add_executable(test_params test_params.c)
 198 target_link_libraries(test_params OpenSSL::Crypto)
 199 add_test(NAME parameters
 200         COMMAND test_params)
 201
 202 add_executable(test_sign test_sign.c)
 203 target_link_libraries(test_sign OpenSSL::Crypto)
 204 add_test(NAME sign/verify
 205         COMMAND test_sign)
 206
 207 add_executable(test_tls test_tls.c)
 208 target_link_libraries(test_tls OpenSSL::SSL)
 209 add_test(NAME TLS
 210         COMMAND test_tls)
 211
 212 add_executable(test_context test_context.c)
 213 target_link_libraries(test_context gost_engine OpenSSL::Crypto)
 214 add_test(NAME context
 215         COMMAND test_context)
 216
 217 add_executable(test_grasshopper test_grasshopper.c)
 218 target_link_libraries(test_grasshopper gost_engine OpenSSL::Crypto)
 219 add_test(NAME grasshopper
 220         COMMAND test_grasshopper)
 221
 222 add_executable(test_keyexpimp test_keyexpimp.c)
 223 #target_compile_definitions(test_keyexpimp PUBLIC -DOPENSSL_LOAD_CONF)
 224 target_link_libraries(test_keyexpimp gost_engine OpenSSL::Crypto)
 225 add_test(NAME keyexpimp
 226         COMMAND test_keyexpimp)
 227
 228 add_executable(test_gost89 test_gost89.c)
 229 target_link_libraries(test_gost89 gost_core)
 230 add_test(NAME gost89
 231         COMMAND test_gost89)
 232
 233 if(NOT SKIP_PERL_TESTS)
 234     execute_process(COMMAND perl -MTest2::V0 -e ""
 235         ERROR_QUIET RESULT_VARIABLE HAVE_TEST2_V0)
 236     if(NOT HAVE_TEST2_V0)
 237         add_test(NAME engine
 238             COMMAND perl run_tests
 239             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/test)
 240         set_tests_properties(engine PROPERTIES ENVIRONMENT
 241             "OPENSSL_ROOT_DIR=${OPENSSL_ROOT_DIR};OPENSSL_ENGINES=${OUTPUT_DIRECTORY};OPENSSL_CONF=${CMAKE_SOURCE_DIR}/test/empty.cnf")
 242     else()
 243       message(STATUS "No Test2::V0 perl module (engine tests skipped)")
 244     endif()
 245 endif()
 246
 247 add_executable(sign benchmark/sign.c)
 248 target_link_libraries(sign gost_core ${CLOCK_GETTIME_LIB})
 249
 250 # All that may need to load just built engine will have path to it defined.
 251 set(BINARY_TESTS_TARGETS
 252         test_digest
 253         test_curves
 254         test_params
 255         test_sign
 256         test_context
 257         test_grasshopper
 258         test_keyexpimp
 259         test_gost89
 260         test_tls
 261         )
 262 set_property(TARGET ${BINARY_TESTS_TARGETS} APPEND PROPERTY COMPILE_DEFINITIONS ENGINE_DIR="${OUTPUT_DIRECTORY}")
 263
 264 add_library(gost_core STATIC ${GOST_LIB_SOURCE_FILES})
 265 set_target_properties(gost_core PROPERTIES POSITION_INDEPENDENT_CODE ON)
 266 target_link_libraries(gost_core PRIVATE OpenSSL::Crypto)
 267
 268 add_library(gost_engine SHARED ${GOST_ENGINE_SOURCE_FILES})
 269 set_target_properties(gost_engine PROPERTIES PREFIX "" OUTPUT_NAME "gost")
 270 set_target_properties(gost_engine PROPERTIES VERSION ${GOST_SOVERSION} SOVERSION ${GOST_SOVERSION})
 271 target_link_libraries(gost_engine PRIVATE gost_core)
 272
 273 add_library(gost_engine_static STATIC ${GOST_ENGINE_SOURCE_FILES})
 274 set_target_properties(gost_engine_static PROPERTIES PREFIX "lib" PUBLIC_HEADER gost-engine.h OUTPUT_NAME "gost")
 275 target_link_libraries(gost_engine_static PRIVATE gost_core)
 276
 277
 278 set(GOST_SUM_SOURCE_FILES
 279         gostsum.c
 280         )
 281
 282 add_executable(gostsum ${GOST_SUM_SOURCE_FILES})
 283 target_link_libraries(gostsum gost_core)
 284
 285 set(GOST_12_SUM_SOURCE_FILES
 286         gost12sum.c
 287         )
 288
 289 add_executable(gost12sum ${GOST_12_SUM_SOURCE_FILES})
 290 target_link_libraries(gost12sum gost_core)
 291
 292 set_source_files_properties(tags PROPERTIES GENERATED true)
 293 add_custom_target(tags
 294     COMMAND ctags -R . ${OPENSSL_ROOT_DIR}
 295     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 296
 297 add_custom_target(tcl_tests
 298     COMMAND ENGINE_DIR=${OUTPUT_DIRECTORY} sh ./runtest.sh
 299     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/tcl_tests)
 300
 301 add_executable(test_tlstree test_tlstree.c)
 302 target_link_libraries(test_tlstree PUBLIC OpenSSL::Crypto)
 303
 304 # install
 305 if (NOT CMAKE_SKIP_INSTALL_RULES)
 306   set(OPENSSL_MAN_INSTALL_DIR ${CMAKE_INSTALL_MANDIR}/man1)
 307
 308   install(TARGETS gost_engine gostsum gost12sum EXPORT GostEngineConfig
 309           LIBRARY  DESTINATION ${OPENSSL_ENGINES_DIR}
 310           RUNTIME  DESTINATION ${CMAKE_INSTALL_BINDIR})
 311   install(FILES gostsum.1 gost12sum.1 DESTINATION ${OPENSSL_MAN_INSTALL_DIR})
 312   if (MSVC)
 313    install(FILES $<TARGET_PDB_FILE:gost_engine> DESTINATION ${OPENSSL_ENGINES_DIR} OPTIONAL)
 314    install(FILES $<TARGET_PDB_FILE:gostsum> $<TARGET_PDB_FILE:gost12sum> DESTINATION   ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 315   endif()
 316 endif()