CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.18 FATAL_ERROR)
   2 project(gost-engine LANGUAGES C)
   3
   4 include(GNUInstallDirs)
   5 include(CheckLibraryExists)
   6 include(CheckFunctionExists)
   7 include(CheckCSourceRuns)
   8
   9 enable_testing()
  10
  11 find_package(OpenSSL 1.1.1 REQUIRED)
  12 include_directories(${OPENSSL_INCLUDE_DIR})
  13
  14 if (CMAKE_C_COMPILER_ID MATCHES "Clang")
  15  add_compile_options(-O2 -Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -ggdb -Qunused-arguments)
  16 elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
  17  add_compile_options(-O2 -Werror -Wall -Wno-unused-parameter -Wno-unused-function -Wno-missing-braces -ggdb -Wno-error=unknown-pragmas)
  18 elseif(CMAKE_C_COMPILER_ID MATCHES "MSVC")
  19  add_definitions(-D_CRT_SECURE_NO_WARNINGS)
  20  add_definitions(-D_CRT_DEPRECATED_NO_WARNINGS)
  21  add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
  22  add_compile_options(/MP /WX /W4 /wd4100 /wd4267 /wd4206 /wd4706 /wd4244 /wd4115)
  23 endif()
  24
  25 if (ASAN)
  26   message(STATUS "address sanitizer enabled")
  27   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=address -g3 -fno-omit-frame-pointer")
  28   set(SKIP_PERL_TESTS 1)
  29 endif()
  30
  31 # DEPRECATEDIN_3_0 CMAC
  32 set_source_files_properties(gost_omac.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  33 # DEPRECATEDIN_3_0 HMAC
  34 set_source_files_properties(gost_keyexpimp.c PROPERTIES COMPILE_FLAGS -Wno-error=deprecated-declarations)
  35
  36 set(CMAKE_C_STANDARD 90)
  37 CHECK_FUNCTION_EXISTS(clock_gettime HAVE_CLOCK_GETTIME_C)
  38 CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_CLOCK_GETTIME_RT)
  39 if(HAVE_CLOCK_GETTIME_RT AND NOT HAVE_CLOCK_GETTIME_C)
  40   set(CLOCK_GETTIME_LIB rt)
  41 endif()
  42
  43 include (TestBigEndian)
  44 TEST_BIG_ENDIAN(IS_BIG_ENDIAN)
  45 if(IS_BIG_ENDIAN)
  46  message(STATUS "BIG_ENDIAN")
  47 else()
  48  message(STATUS "LITTLE_ENDIAN")
  49  add_definitions(-DL_ENDIAN)
  50 endif()
  51
  52 check_c_source_runs("
  53   #ifdef _MSC_VER
  54   # include <intrin.h>
  55   #else
  56   # include <x86intrin.h>
  57   #endif
  58   int main(void) {
  59     unsigned long long x = -1, y = 1, r;
  60     unsigned char cf;
  61     cf = _addcarry_u64(1, x, y, &r);
  62     return !(cf == 1 && r == 1);
  63   }
  64   " ADDCARRY_U64)
  65 if (ADDCARRY_U64)
  66   add_definitions(-DHAVE_ADDCARRY_U64)
  67 endif()
  68
  69 check_c_source_runs("
  70   int main(void) {
  71     char buf[16] = { 0, 1, 2 };
  72     int *p = (int *)(buf + 1);
  73     int *q = (int *)(buf + 2);
  74     return (*p == *q);
  75   }
  76   " RELAXED_ALIGNMENT)
  77 if (NOT RELAXED_ALIGNMENT)
  78   add_definitions(-DSTRICT_ALIGNMENT)
  79 endif()
  80
  81 set(BIN_DIRECTORY bin)
  82
  83 # Same soversion as OpenSSL
  84 set(GOST_SOVERSION "${OPENSSL_VERSION_MAJOR}.${OPENSSL_VERSION_MINOR}")
  85
  86 set(OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${BIN_DIRECTORY})
  87
  88 #set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  89 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  90 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${OUTPUT_DIRECTORY})
  91
  92 # Remove when https://gitlab.kitware.com/cmake/cmake/issues/18525 is addressed
  93 set(OPENSSL_ENGINES_DIR "" CACHE PATH "OpenSSL Engines Directory")
  94 if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
  95         include(FindPkgConfig)
  96         pkg_get_variable(OPENSSL_ENGINES_DIR libcrypto enginesdir)
  97         if ("${OPENSSL_ENGINES_DIR}" STREQUAL "")
  98                 message( FATAL_ERROR "Unable to discover the OpenSSL engines directory. Provide the path using -DOPENSSL_ENGINES_DIR" )
  99         endif()
 100 endif()
 101
 102 set(GOST_89_SOURCE_FILES
 103         gost89.c
 104         gost89.h
 105         )
 106
 107 set(GOST_HASH_SOURCE_FILES
 108         gosthash.c
 109         gosthash.h
 110         )
 111
 112 set(GOST_HASH_2012_SOURCE_FILES
 113         gosthash2012.c
 114         gosthash2012.h
 115         gosthash2012_const.h
 116         gosthash2012_precalc.h
 117         gosthash2012_ref.h
 118         gosthash2012_sse2.h
 119         )
 120
 121 set(GOST_GRASSHOPPER_SOURCE_FILES
 122         gost_grasshopper.h
 123         gost_grasshopper_core.h
 124         gost_grasshopper_core.c
 125         gost_grasshopper_defines.h
 126         gost_grasshopper_defines.c
 127         gost_grasshopper_math.h
 128         gost_grasshopper_galois_precompiled.c
 129         gost_grasshopper_precompiled.c
 130         gost_grasshopper_cipher.h
 131         gost_grasshopper_cipher.c
 132         )
 133
 134 set(GOST_CORE_SOURCE_FILES
 135         e_gost_err.c
 136         e_gost_err.h
 137         gost_asn1.c
 138         gost_crypt.c
 139         gost_ctl.c
 140         gost_eng.c
 141         gost_lcl.h
 142         gost_params.c
 143         )
 144
 145 set(GOST_EC_SOURCE_FILES
 146         gost_ec_keyx.c
 147         gost_ec_sign.c
 148         ecp_id_GostR3410_2001_CryptoPro_A_ParamSet.c
 149         ecp_id_GostR3410_2001_CryptoPro_B_ParamSet.c
 150         ecp_id_GostR3410_2001_CryptoPro_C_ParamSet.c
 151         ecp_id_GostR3410_2001_TestParamSet.c
 152         ecp_id_tc26_gost_3410_2012_256_paramSetA.c
 153         ecp_id_tc26_gost_3410_2012_512_paramSetA.c
 154         ecp_id_tc26_gost_3410_2012_512_paramSetB.c
 155         ecp_id_tc26_gost_3410_2012_512_paramSetC.c
 156         )
 157
 158 set (GOST_OMAC_SOURCE_FILES
 159         gost_omac.c
 160         gost_omac_acpkm.c
 161         )
 162
 163 set(GOST_LIB_SOURCE_FILES
 164         ${GOST_89_SOURCE_FILES}
 165         ${GOST_HASH_SOURCE_FILES}
 166         ${GOST_HASH_2012_SOURCE_FILES}
 167         ${GOST_GRASSHOPPER_SOURCE_FILES}
 168         ${GOST_EC_SOURCE_FILES}
 169         ${GOST_OMAC_SOURCE_FILES}
 170         gost_keyexpimp.c
 171         gost_keywrap.c
 172         gost_keywrap.h
 173         )
 174
 175 set(GOST_ENGINE_SOURCE_FILES
 176         ${GOST_CORE_SOURCE_FILES}
 177         gost_ameth.c
 178         gost_md.c
 179         gost_md2012.c
 180         gost_pmeth.c
 181         gost_omac.c
 182         gost_omac_acpkm.c
 183         )
 184
 185 add_executable(test_digest test_digest.c)
 186 target_link_libraries(test_digest OpenSSL::Crypto)
 187 add_test(NAME digest
 188         COMMAND test_digest)
 189
 190 add_executable(test_curves test_curves.c)
 191 target_link_libraries(test_curves gost_engine gost_core)
 192 add_test(NAME curves
 193         COMMAND test_curves)
 194
 195 add_executable(test_params test_params.c)
 196 target_link_libraries(test_params OpenSSL::Crypto)
 197 add_test(NAME parameters
 198         COMMAND test_params)
 199
 200 add_executable(test_sign test_sign.c)
 201 target_link_libraries(test_sign OpenSSL::Crypto)
 202 add_test(NAME sign/verify
 203         COMMAND test_sign)
 204
 205 add_executable(test_tls test_tls.c)
 206 target_link_libraries(test_tls OpenSSL::SSL)
 207 add_test(NAME TLS
 208         COMMAND test_tls)
 209
 210 add_executable(test_context test_context.c)
 211 target_link_libraries(test_context gost_engine gost_core OpenSSL::Crypto)
 212 add_test(NAME context
 213         COMMAND test_context)
 214
 215 add_executable(test_grasshopper test_grasshopper.c)
 216 target_link_libraries(test_grasshopper gost_engine gost_core OpenSSL::Crypto)
 217 add_test(NAME grasshopper
 218         COMMAND test_grasshopper)
 219
 220 add_executable(test_keyexpimp test_keyexpimp.c)
 221 #target_compile_definitions(test_keyexpimp PUBLIC -DOPENSSL_LOAD_CONF)
 222 target_link_libraries(test_keyexpimp gost_engine gost_core)
 223 add_test(NAME keyexpimp
 224         COMMAND test_keyexpimp)
 225
 226 add_executable(test_gost89 test_gost89.c)
 227 target_link_libraries(test_gost89 gost_core)
 228 add_test(NAME gost89
 229         COMMAND test_gost89)
 230
 231 if(NOT SKIP_PERL_TESTS)
 232     execute_process(COMMAND perl -MTest2::V0 -e ""
 233         ERROR_QUIET RESULT_VARIABLE HAVE_TEST2_V0)
 234     if(NOT HAVE_TEST2_V0)
 235         add_test(NAME engine
 236             COMMAND perl run_tests
 237             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/test)
 238         set_tests_properties(engine PROPERTIES ENVIRONMENT
 239             "OPENSSL_ROOT_DIR=${OPENSSL_ROOT_DIR};OPENSSL_ENGINES=${OUTPUT_DIRECTORY};OPENSSL_CONF=${CMAKE_SOURCE_DIR}/test/empty.cnf")
 240     else()
 241       message(STATUS "No Test2::V0 perl module (engine tests skipped)")
 242     endif()
 243 endif()
 244
 245 add_executable(sign benchmark/sign.c)
 246 target_link_libraries(sign gost_core ${CLOCK_GETTIME_LIB})
 247
 248 # All that may need to load just built engine will have path to it defined.
 249 set(BINARY_TESTS_TARGETS
 250         test_digest
 251         test_curves
 252         test_params
 253         test_sign
 254         test_context
 255         test_grasshopper
 256         test_keyexpimp
 257         test_gost89
 258         test_tls
 259         )
 260 set_property(TARGET ${BINARY_TESTS_TARGETS} APPEND PROPERTY COMPILE_DEFINITIONS ENGINE_DIR="${OUTPUT_DIRECTORY}")
 261
 262 add_library(gost_core STATIC ${GOST_LIB_SOURCE_FILES})
 263 set_target_properties(gost_core PROPERTIES POSITION_INDEPENDENT_CODE ON)
 264 target_link_libraries(gost_core PRIVATE OpenSSL::Crypto)
 265
 266 add_library(gost_engine SHARED ${GOST_ENGINE_SOURCE_FILES})
 267 set_target_properties(gost_engine PROPERTIES PREFIX "" OUTPUT_NAME "gost")
 268 set_target_properties(gost_engine PROPERTIES VERSION ${GOST_SOVERSION} SOVERSION ${GOST_SOVERSION})
 269 target_link_libraries(gost_engine PRIVATE gost_core)
 270
 271 add_library(gost_engine_static STATIC ${GOST_ENGINE_SOURCE_FILES})
 272 set_target_properties(gost_engine_static PROPERTIES PREFIX "lib" PUBLIC_HEADER gost-engine.h OUTPUT_NAME "gost")
 273 target_link_libraries(gost_engine_static PRIVATE gost_core)
 274
 275
 276 set(GOST_SUM_SOURCE_FILES
 277         gostsum.c
 278         )
 279
 280 add_executable(gostsum ${GOST_SUM_SOURCE_FILES})
 281 target_link_libraries(gostsum gost_core)
 282
 283 set(GOST_12_SUM_SOURCE_FILES
 284         gost12sum.c
 285         )
 286
 287 add_executable(gost12sum ${GOST_12_SUM_SOURCE_FILES})
 288 target_link_libraries(gost12sum gost_core)
 289
 290 set_source_files_properties(tags PROPERTIES GENERATED true)
 291 add_custom_target(tags
 292     COMMAND ctags -R . ${OPENSSL_ROOT_DIR}
 293     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 294
 295 add_custom_target(tcl_tests
 296     COMMAND ENGINE_DIR=${OUTPUT_DIRECTORY} sh ./runtest.sh
 297     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/tcl_tests)
 298
 299 add_executable(test_tlstree test_tlstree.c)
 300 target_link_libraries(test_tlstree PUBLIC OpenSSL::Crypto)
 301
 302 # install
 303 set(OPENSSL_MAN_INSTALL_DIR ${CMAKE_INSTALL_MANDIR}/man1)
 304
 305 install(TARGETS gost_engine gostsum gost12sum EXPORT GostEngineConfig
 306         LIBRARY  DESTINATION ${OPENSSL_ENGINES_DIR}
 307         RUNTIME  DESTINATION ${CMAKE_INSTALL_BINDIR})
 308 install(FILES gostsum.1 gost12sum.1 DESTINATION ${OPENSSL_MAN_INSTALL_DIR})
 309 if (MSVC)
 310  install(FILES $<TARGET_PDB_FILE:gost_engine> DESTINATION ${OPENSSL_ENGINES_DIR} OPTIONAL)
 311  install(FILES $<TARGET_PDB_FILE:gostsum> $<TARGET_PDB_FILE:gost12sum> DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 312 endif()